#!/usr/bin/perl -w

eval 'exec /usr/bin/perl -w -S $0 ${1+"$@"}'
    if 0; # not running under some shell
#
# Project Builder main application
#
# $Id$
#
# Copyright B. Cornec 2007
# Provided under the GPL v2

# Syntax: see at end

use strict 'vars';
use Getopt::Long qw(:config auto_abbrev no_ignore_case);
use Pod::Usage;
use Data::Dumper;
use English;
use File::Basename;
use File::Copy;
use Time::localtime qw(localtime);
use POSIX qw(strftime);

# Global variables
use lib qw (lib);
use ProjectBuilder::Distribution;
use ProjectBuilder::Version;
use ProjectBuilder::Base;

my %opts;					# CLI Options
my $action;					# action to realize
my $test = "FALSE";			# Not used
my $force = 0;				# Force VE/VM rebuild
my $option = "";			# Not used
my @pkgs;					# list of packages
my $pbtag;					# Global Tag variable
my $pbver;					# Global Version variable
my $pbscript;				# Name of the script
my %pbver;					# per package
my %pbtag;					# per package
my $pbrev;					# Global REVISION variable
my $pbaccount;				# Login to use to connect to the VM
my $pbport;					# Port to use to connect to the VM
my $newver;					# New version to create
my $iso;					# ISO image for the VM to create

my @date = pb_get_date();
my $pbdate = strftime("%Y-%m-%d", @date);

=pod

=head1 NAME

pb, aka project-builder.org - builds packages for your projects

=head1 DESCRIPTION

pb helps you build various packages directly from your project sources. 
Those sources could be handled by a CMS (Configuration Management System)
such as Subversion, CVS, ... or being a simple reference to a compressed tar file.
It's based on a set of configuration files, a set of provided macros to help 
you keeping build files as generic as possible. For example, a single .spec
file should be required to generate for all rpm based distributions, even 
if you could also have multiple .spec files if required.

=head1 SYNOPSIS

pb [-vhq][-r pbroot][-p project][[-s script -a account -P port][-m mach-1[,...]]][-i iso] <action> [<pkg1> ...]

pb [--verbose][--help][--man][--quiet][--revision pbroot][--project project][[--script script --account account --port port][--machine mach-1[,...]]][--iso iso] <action> [<pkg1> ...]

=head1 OPTIONS

=over 4

=item B<-v|--verbose>

Print a brief help message and exits.

=item B<-q|--quiet>

Do not print any output.

=item B<-h|--help>

Print a brief help message and exits.

=item B<--man>

Prints the manual page and exits.

=item B<-m|--machine machine1[,machine2,...]>

Name of the Virtual Machines (VM) or Virtual Environments (VE) you want to build on (coma separated). 
All if none precised (or use the env variable PBV).

=item B<-s|--script script>

Name of the script you want to execute on the related VMs or VEs.

=item B<-i|--iso iso_image>

Name of the ISO image of the distribution you want to install on the related VMs.

=item B<-a|--account account>

Name of the account to use to connect on the related VMs.

=item B<-P|--port port_number>

Port number to use to connect on the related VMs.\n";

=item B<-p|--project project_name>

Name of the project you're working on (or use the env variable PBPROJ)

=item B<-r|--revision revision>

Path Name of the project revision under the CMS (or use the env variable PBROOT)

=item B<-V|--version new_version>

New version of the project to create based on the current one.

=back 

=head1 ARGUMENTS

<action> can be:

=over 4

=item B<cms2build>

Create tar files for the project under your CMS. 
CMS supported are SVN and CVS
parameters are packages to build
if not using default list

=item B<build2pkg>

Create packages for your running distribution

=item B<cms2pkg>

cms2build + build2pkg

=item B<build2ssh>

Send the tar files to a SSH host

=item B<cms2ssh>

cms2build + build2ssh

=item B<pkg2ssh>

Send the packages built to a SSH host

=item B<build2vm>

Create packages in VMs, launching them if needed
and send those packages to a SSH host once built
VM type supported are QEMU

=item B<build2ve>

Create packages in VEs, creating it if needed
and send those packages to a SSH host once built

=item B<cms2vm>

cms2build + build2vm

=item B<cms2ve>

cms2build + build2ve

=item B<launchvm>

Launch one virtual machine

=item B<launchve>

Launch one virtual environment

=item B<script2vm>

Launch one virtual machine if needed
and executes a script on it

=item B<script2ve>

Execute a script in a virtual environment

=item B<newvm>

Create a new virtual machine

=item B<newve>

Create a new virtual environment

=item B<setupvm>

Setup a virtual machine for pb usage

=item B<setupve>

Setup a virtual environment for pb usage

=item B<newver>

Create a new version of the project derived
from the current one

=item B<newproj>

Create a new project and a template set of
configuration files under pbconf

=back 

<pkgs> can be a list of packages, the keyword 'all' or nothing, in which case the default list of packages is taken (corresponding to the defpkgdir list of arguments in the configuration file).

=head1 WEB SITES

The main Web site of the project is available at L<http://www.project-builder.org/>. Bug reports should be filled using the trac instance of the project at L<http://trac.project-builder.org/>.

=head1 USER MAILING LIST

None exists for the moment.

=head1 CONFIGURATION FILES

Each pb user may have a configuration in F<$HOME/.pbrc>. The values in this file may overwrite any other configuration file value. 

Here is an example of such a configuration file:

 #
 # Define for each project the URL of its pbconf repository
 # No default option allowed here as they need to be all different
 #
 # URL of the pbconf content
 # This is the format of a classical URL with the extension of additional schema such as 
 # svn+ssh, cvs+ssh, ...
 #
 pbconfurl linuxcoe = cvs+ssh://:ext:bcornec@linuxcoe.cvs.sourceforge.net:/cvsroot/linuxcoe/pbconf

 # This is normaly defined in the project's configuration file
 # Url of the project
 #
 pburl linuxcoe = cvs+ssh://:ext:bcornec@linuxcoe.cvs.sourceforge.net:/cvsroot/linuxcoe
 
 # All these URLs needs to be defined here as the are the entry point 
 # for how to build packages for the project
 #
 pbconfurl pb = svn+ssh://svn.project-builder.org/mondo/svn/pb/pbconf
 pbconfurl mondorescue = svn+ssh://svn.project-builder.org/mondo/svn/project-builder/mondorescue/pbconf
 pbconfurl collectl = svn+ssh://bruno@svn.mondorescue.org/mondo/svn/project-builder/collectl/pbconf
 pbconfurl netperf = svn+ssh://svn.mondorescue.org/mondo/svn/project-builder/netperf/pbconf
 
 # Under that dir will take place everything related to pb
 # If you want to use VMs/chroot/..., then use $ENV{'HOME'} to make it portable
 # to your VMs/chroot/...
 # if not defined then /var/cache
 pbdefdir default = $ENV{'HOME'}/project-builder
 pbdefdir pb = $ENV{'HOME'}
 pbdefdir linuxcoe = $ENV{'HOME'}/LinuxCOE/cvs
 pbdefdir mondorescue = $ENV{'HOME'}/mondo/svn
 
 # pbconfdir points to the directory where the CMS content of the pbconfurl is checked out
 # If not defined, pbconfdir is under pbdefdir/pbproj/pbconf
 pbconfdir linuxcoe = $ENV{'HOME'}/LinuxCOE/cvs/pbconf
 pbconfdir mondorescue = $ENV{'HOME'}/mondo/svn/pbconf
 
 # pbdir points to the directory where the CMS content of the pburl is checked out
 # If not defined, pbdir is under pbdefdir/pbproj
 # Only defined if we have access to the dev of the project
 pbdir linuxcoe = $ENV{'HOME'}/LinuxCOE/cvs
 pbdir mondorescue = $ENV{'HOME'}/mondo/svn
 
 # -daemonize doesn't work with qemu 0.8.2
 vmopt default = -m 384

=head1 AUTHORS

The Project-Builder.org team L<http://trac.project-builder.org/> lead by Bruno Cornec L<mailto:bruno@project-builder.org>.

=head1 COPYRIGHT

Project-Builder.org is distributed under the GPL v2.0 license
described in the file C<COPYING> included with the distribution.

=cut

# ---------------------------------------------------------------------------

# Old syntax
#getopts('a:fhi:l:m:P:p:qr:s:vV:',\%opts);

my ($projectbuilderver,$projectbuilderrev) = pb_version_init();

GetOptions("help|?|h" => \$opts{'h'}, 
		"man" => \$opts{'man'},
		"verbose|v+" => \$opts{'v'},
		"quiet|q" => \$opts{'q'},
		"log-files|l=s" => \$opts{'l'},
		"force|f" => \$opts{'f'},
		"account|a=s" => \$opts{'a'},
		"revision|r=s" => \$opts{'r'},
		"script|s=s" => \$opts{'s'},
		"machines|mock|m=s" => \$opts{'m'},
		"port|P=i" => \$opts{'P'},
		"project|p=s" => \$opts{'p'},
		"iso|i=s" => \$opts{'i'},
		"version|V=s" => \$opts{'V'},
) || pb_syntax(-1,0);

if (defined $opts{'h'}) {
	pb_syntax(0,1);
}
if (defined $opts{'man'}) {
	pb_syntax(0,2);
}
if (defined $opts{'v'}) {
	$debug = $opts{'v'};
	pb_log(0,"Debug value: $debug\n");
}
if (defined $opts{'f'}) {
	$force=1;
}
if (defined $opts{'q'}) {
	$debug=-1;
}
if (defined $opts{'l'}) {
	open(LOG,"> $opts{'l'}") || die "Unable to log to $opts{'l'}: $!";
	$LOG = *LOG;
	$debug = 0  if ($debug == -1);
	}
pb_log_init($debug, $LOG);

# Handle root of the project if defined
if (defined $opts{'r'}) {
	$ENV{'PBROOTDIR'} = $opts{'r'};
}
# Handle virtual machines if any
if (defined $opts{'m'}) {
	$ENV{'PBV'} = $opts{'m'};
}
if (defined $opts{'s'}) {
	$pbscript = $opts{'s'};
}
if (defined $opts{'a'}) {
	$pbaccount = $opts{'a'};
	die "option -a requires a -s script option" if (not defined $pbscript);
}
if (defined $opts{'P'}) {
	$pbport = $opts{'P'};
}
if (defined $opts{'V'}) {
	$newver = $opts{'V'};
}
if (defined $opts{'i'}) {
	$iso = $opts{'i'};
}

# Get Action
$action = shift @ARGV;
die pb_syntax(-1,1) if (not defined $action);

my ($filteredfiles, $supfiles, $defpkgdir, $extpkgdir);
my $pbinit = undef;
$pbinit = 1 if ($action =~ /^newproj$/);

# Handles project name if any
# And get global params
if (defined $opts{'p'}) {
	($filteredfiles, $supfiles, $defpkgdir, $extpkgdir) 
	= pb_env_init($opts{'p'},$pbinit);
} else {
	($filteredfiles, $supfiles, $defpkgdir, $extpkgdir) 
	= pb_env_init(undef,$pbinit);
}

pb_log(0,"Project: $ENV{'PBPROJ'}\n");
pb_log(0,"Action: $action\n");

# Keep those project values to store them at the end each time
my $pbprojtag = $ENV{'PBTAG'};
my $pbprojver = $ENV{'PBVER'};

# Act depending on action
if ($action =~ /^cms2build$/) {
	pb_cms2build();
} elsif ($action =~ /^build2pkg$/) {
	pb_build2pkg();
} elsif ($action =~ /^cms2pkg$/) {
	pb_cms2build();
	pb_build2pkg();
} elsif ($action =~ /^build2ssh$/) {
	pb_build2ssh();
} elsif ($action =~ /^cms2ssh$/) {
	pb_cms2build();
	pb_build2ssh();
} elsif ($action =~ /^pkg2ssh$/) {
	pb_pkg2ssh();
} elsif ($action =~ /^build2ve$/) {
	pb_build2v("ve");
} elsif ($action =~ /^build2vm$/) {
	pb_build2v("vm");
} elsif ($action =~ /^cms2ve$/) {
	pb_cms2build();
	pb_build2v("ve");
} elsif ($action =~ /^cms2vm$/) {
	pb_cms2build();
	pb_build2v("vm");
} elsif ($action =~ /^launchvm$/) {
	pb_launchv("vm",$ENV{'PBV'},0);
} elsif ($action =~ /^launchve$/) {
	pb_launchv("ve",$ENV{'PBV'},0);
} elsif ($action =~ /^script2vm$/) {
	pb_script2v($pbscript,"vm");
} elsif ($action =~ /^script2ve$/) {
	pb_script2v($pbscript,"ve");
} elsif ($action =~ /^newver$/) {
	pb_newver();
} elsif ($action =~ /^newve$/) {
	pb_launchv("ve",$ENV{'PBV'},1);
} elsif ($action =~ /^newvm$/) {
	pb_launchv("vm",$ENV{'PBV'},1);
} elsif ($action =~ /^setupve$/) {
	my $pbscript = pb_setup_v("ve");
	pb_script2v($pbscript,"ve");
} elsif ($action =~ /^setupvm$/) {
	my $pbscript = pb_setup_v("vm");
	pb_script2v($pbscript,"vm");
} elsif ($action =~ /^newproj$/) {
	# Nothing to do - already done in pb_env_init
} elsif ($action =~ /^clean$/) {
} else {
	pb_log(0,"\'$action\' is not available\n");
	pb_syntax(-2,1);
}

sub pb_cms2build {

	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;

	my ($scheme, $uri) = pb_cms_init($pbinit);

	my ($pkgv, $pkgt) = pb_conf_get_if("pkgver","pkgtag");

	# declare packager for filtering
	my ($tmp) = pb_conf_get("pbpackager");
	my $pbpackager = $tmp->{$ENV{'PBPROJ'}};

	foreach my $pbpkg (@pkgs) {
		$ENV{'PBPKG'} = $pbpkg;
		$ENV{'PBVER'} = $pbprojver;
		$ENV{'PBTAG'} = $pbprojtag;
		if ((defined $pkgv) && (defined $pkgv->{$pbpkg})) {
			$pbver = $pkgv->{$pbpkg};
			$ENV{'PBVER'} = $pbver;
		} else {
			$pbver = $ENV{'PBVER'};
		}
		if ((defined $pkgt) && (defined $pkgt->{$pbpkg})) {
			$pbtag = $pkgt->{$pbpkg};
			$ENV{'PBTAG'} = $pbtag;
		} else {
			$pbtag = $ENV{'PBTAG'};
		}

		$pbrev = $ENV{'PBREVISION'};
		pb_log(0,"\n");
		pb_log(0,"Management of $pbpkg $pbver-$pbtag (rev $pbrev)\n");
		die "Unable to get env var PBDESTDIR" if (not defined $ENV{'PBDESTDIR'});
		# Clean up dest if necessary. The export will recreate it
		my $dest = "$ENV{'PBDESTDIR'}/$pbpkg-$pbver";
		pb_rm_rf($dest) if (-d $dest);

		# Export CMS tree for the concerned package to dest
		# And generate some additional files
		$OUTPUT_AUTOFLUSH=1;

		# computes in which dir we have to work
		my $dir = $defpkgdir->{$pbpkg};
		$dir = $extpkgdir->{$pbpkg} if (not defined $dir);
		pb_log(2,"def:".Dumper($defpkgdir)." ext: ".Dumper($extpkgdir)." \n");

		# Exporting from CMS
		pb_cms_export($uri,"$ENV{'PBDIR'}/$dir",$dest);

		# Get project info on authors and log file
		my $chglog = "$ENV{'PBROOTDIR'}/$pbpkg/pbcl";
		$chglog = "$ENV{'PBROOTDIR'}/pbcl" if (! -f $chglog);
		$chglog = undef if (! -f $chglog);

		my $authors = "$ENV{'PBROOTDIR'}/$pbpkg/pbauthors";
		$authors = "$ENV{'PBROOTDIR'}/pbauthors" if (! -f $authors);
		$authors = "/dev/null" if (! -f $authors);

		# Extract cms log history and store it
		if ((defined $chglog) && (! -f "$dest/NEWS")) {
			pb_log(2,"Generating NEWS file from $chglog\n");
			copy($chglog,"$dest/NEWS") || die "Unable to create $dest/NEWS";
		}
		pb_cms_log($scheme,"$ENV{'PBDIR'}/$dir",$dest,$chglog,$authors);

		my %build;

		my @pt;
		@pt = pb_conf_get_if("vmlist","velist");
		my $tmpl = "";
		if (defined $pt[0]->{$ENV{'PBPROJ'}}) {
			$tmpl .= $pt[0]->{$ENV{'PBPROJ'}};
		}
		if (defined $pt[1]->{$ENV{'PBPROJ'}}) {
			# the 2 lists needs to be grouped with a ',' separated them
			if ($tmpl ne "") {
				$tmpl .= ",";
			}
			$tmpl .= $pt[1]->{$ENV{'PBPROJ'}} 
		}
		foreach my $d (split(/,/,$tmpl)) {
			my ($name,$ver,$arch) = split(/-/,$d);
			chomp($arch);
			my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init($name,$ver);
			pb_log(2,"DEBUG: distro tuple: ".Dumper($ddir, $dver, $dfam, $dtype, $pbsuf)."\n");
			pb_log(2,"DEBUG Filtering PBDATE => $pbdate, PBTAG => $pbtag, PBVER => $pbver\n");

			# Filter build files from the less precise up to the most with overloading
			# Filter all files found, keeping the name, and generating in dest

			# Find all build files first relatively to PBROOTDIR
			# Find also all specific files referenced in the .pb conf file
			my %bfiles = ();
			my %pkgfiles = ();
			$build{"$ddir-$dver"} = "yes";

			if (-d "$ENV{'PBROOTDIR'}/$pbpkg/$dtype") {
				pb_list_bfiles("$ENV{'PBROOTDIR'}/$pbpkg/$dtype",$pbpkg,\%bfiles,\%pkgfiles,$supfiles);
			} elsif (-d "$ENV{'PBROOTDIR'}/$pbpkg/$dfam") {
				pb_list_bfiles("$ENV{'PBROOTDIR'}/$pbpkg/$dfam",$pbpkg,\%bfiles,\%pkgfiles,$supfiles);
			} elsif (-d "$ENV{'PBROOTDIR'}/$pbpkg/$ddir") {
				pb_list_bfiles("$ENV{'PBROOTDIR'}/$pbpkg/$ddir",$pbpkg,\%bfiles,\%pkgfiles,$supfiles);
			} elsif (-d "$ENV{'PBROOTDIR'}/$pbpkg/$ddir-$dver") {
				pb_list_bfiles("$ENV{'PBROOTDIR'}/$pbpkg/$ddir-$dver",$pbpkg,\%bfiles,\%pkgfiles,$supfiles);
			} else {
				$build{"$ddir-$dver"} = "no";
				next;
			}
			pb_log(2,"DEBUG bfiles: ".Dumper(\%bfiles)."\n");

			# Get all filters to apply
			my $ptr = pb_get_filters($pbpkg, $dtype, $dfam, $ddir, $dver);

			# Apply now all the filters on all the files concerned
			# destination dir depends on the type of file
			if (defined $ptr) {
				foreach my $f (values %bfiles,values %pkgfiles) {
					pb_filter_file_pb("$ENV{'PBROOTDIR'}/$f",$ptr,"$dest/pbconf/$ddir-$dver/".basename($f),$dtype,$pbsuf,$ENV{'PBPROJ'},$pbpkg,$pbver,$pbtag,$pbrev,$pbdate,$defpkgdir,$extpkgdir,$pbpackager,$chglog);
				}
			}
		}
		my @found;
		my @notfound;
		foreach my $b (keys %build) {
			push @found,$b if ($build{$b} =~ /yes/);
			push @notfound,$b if ($build{$b} =~ /no/);
		}
		pb_log(0,"Build files generated for ".join(',',@found)."\n");
		pb_log(0,"No Build files found for ".join(',',@notfound)."\n") if (@notfound);
		# Get the generic filter (all.pbf) and 
		# apply those to the non-build files including those
		# generated by pbinit if applicable

		# Get only all.pbf filter
		$ptr = pb_get_filters($pbpkg);

		my $liste ="";
		if (defined $filteredfiles->{$pbpkg}) {
			foreach my $f (split(/,/,$filteredfiles->{$pbpkg})) {
				pb_filter_file_inplace($ptr,"$dest/$f",$ENV{'PBPROJ'},$pbpkg,$pbver,$pbtag,$pbrev,$pbdate,$pbpackager);
				$liste = "$f $liste";
			}
		}
		pb_log(2,"Files ".$liste."have been filtered\n");

		# Prepare the dest directory for archive
		if (-x "$ENV{'PBROOTDIR'}/$pbpkg/pbinit") {
			pb_filter_file("$ENV{'PBROOTDIR'}/$pbpkg/pbinit",$ptr,"$ENV{'PBTMP'}/pbinit",$ENV{'PBPROJ'},$pbpkg,$pbver,$pbtag,$pbrev,$pbdate,$pbpackager);
			chmod 0755,"$ENV{'PBTMP'}/pbinit";
			pb_system("cd $dest ; $ENV{'PBTMP'}/pbinit","Executing init script from $ENV{'PBROOTDIR'}/$pbpkg/pbinit");
		}

		# Archive dest dir
		chdir "$ENV{'PBDESTDIR'}" || die "Unable to change dir to $ENV{'PBDESTDIR'}";
		# Possibility to look at PBSRC to guess more the filename
		pb_system("tar cfz $pbpkg-$pbver.tar.gz $pbpkg-$pbver","Creating $pbpkg tar files compressed");
		pb_log(0,"Under $ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz\n");

		# Keep track of what is generated by default
		open(LAST,"> $ENV{'PBDESTDIR'}/pbrc") || die "Unable to create $ENV{'PBDESTDIR'}/pbrc";
		#print LAST "pbroot $pbprojver-$pbprojtag = $ENV{'PBROOTDIR'}\n";
		# Why not use pbproj ?
		print LAST "pbroot $ENV{'PBPROJ'} = $ENV{'PBROOTDIR'}\n";
		close(LAST);

		# Keep track of per package version
		my ($pkg) = pb_conf_read_if("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
		$pkg = { } if (not defined $pkg);
		if ((not defined $pkg->{$pbpkg}) || ($pkg->{$pbpkg} ne "$pbver-$pbtag")) {
			$pkg->{$pbpkg} = "$pbver-$pbtag";
		}

		pb_log(2,"DEBUG pkg: ".Dumper($pkg)."\n");
		open(PKG,"> $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb") || die "Unable to create $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb";
		foreach my $p (keys %$pkg) {
			print PKG "pbpkg $p = $pkg->{$p}\n";
		}
		close(PKG);

		# Final cleanup
		pb_rm_rf($dest) if (-d $dest);
	}
}

sub pb_build2pkg {

	# Get list of packages to build
	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;

	# Get the running distro to build on
	my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init();
	pb_log(2,"DEBUG: distro tuple: ".join(',',($ddir, $dver, $dfam, $dtype, $pbsuf))."\n");

	# Get content saved in cms2build
	my ($pkg) = pb_conf_read("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
	$pkg = { } if (not defined $pkg);

	# declare packager (via env var in VM/VE
	my $pbpackager;
	if (not defined $ENV{'PBPACKAGER'}) {
		my ($tmp) = pb_conf_get("pbpackager");
		$pbpackager = $tmp->{$ENV{'PBPROJ'}};
	} else {
		$pbpackager = $ENV{'PBPACKAGER'};
	}

	chdir "$ENV{'PBBUILDDIR'}";
	my $made = ""; # pkgs made during build
	foreach my $pbpkg (@pkgs) {
		my $vertag = $pkg->{$pbpkg};
		# get the version of the current package - maybe different
		($pbver,$pbtag) = split(/-/,$vertag);

		my $src="$ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz";
		pb_log(2,"Source file: $src\n");

		pb_log(2,"Working directory: $ENV{'PBBUILDDIR'}\n");
		if ($dtype eq "rpm") {
			foreach my $d ('RPMS','SRPMS','SPECS','SOURCES','BUILD') {
				if (! -d "$ENV{'PBBUILDDIR'}/$d") {
				pb_mkdir_p("$ENV{'PBBUILDDIR'}/$d") || die "Please ensure that you can write into $ENV{'PBBUILDDIR'} to create $d\nchown the $ENV{'PBBUILDDIR'} directory to your uid";
				}
			}

			# Remove in case a previous link/file was there
			unlink "$ENV{'PBBUILDDIR'}/SOURCES/".basename($src);
			symlink "$src","$ENV{'PBBUILDDIR'}/SOURCES/".basename($src) || die "Unable to symlink $src in $ENV{'PBBUILDDIR'}/SOURCES";
			# We need to first extract the spec file
			my @specfile;
			@specfile = pb_extract_build_files($src,"$pbpkg-$pbver/pbconf/$ddir-$dver/","$ENV{'PBBUILDDIR'}/SPECS");

			pb_log(2,"specfile: ".Dumper(\@specfile)."\n");
			# set LANGUAGE to check for correct log messages
			$ENV{'LANGUAGE'}="C";
			foreach my $f (@specfile) {
				if ($f =~ /\.spec$/) {
					pb_system("rpmbuild --define \'packager $pbpackager\' --define \"_topdir $ENV{'PBBUILDDIR'}\" -ba $f","Building package with $f under $ENV{'PBBUILDDIR'}");
					last;
				}
			}
			$made="$made RPMS/*/$pbpkg-$pbver-$pbtag$pbsuf.*.rpm SRPMS/$pbpkg-$pbver-$pbtag$pbsuf.src.rpm";
			if (-f "/usr/bin/rpmlint") {
				pb_system("rpmlint $made","Checking validity of rpms with rpmlint");
			}
		} elsif ($dtype eq "deb") {
			chdir "$ENV{'PBBUILDDIR'}" || die "Unable to chdir to $ENV{'PBBUILDDIR'}";
			pb_system("tar xfz $src","Extracting sources");

			chdir "$pbpkg-$pbver" || die "Unable to chdir to $pbpkg-$pbver";
			pb_rm_rf("debian");
			symlink "pbconf/$ddir-$dver","debian" || die "Unable to symlink to pbconf/$ddir-$dver";
			chmod 0755,"debian/rules";
			pb_system("dpkg-buildpackage -us -uc -rfakeroot","Building package");
			$made="$made $pbpkg"."_*.deb $pbpkg"."_*.dsc $pbpkg"."_*.tar.gz";
			if (-f "/usr/bin/lintian") {
				pb_system("lintian $made","Checking validity of debs with lintian");
			}
		} elsif ($dtype eq "ebuild") {
			my @ebuildfile;
			# For gentoo we need to take pb as subsystem name
			# We put every apps here under sys-apps. hope it's correct
			# We use pb's home dir in order o have a single OVERLAY line
			my $tmpd = "$ENV{'HOME'}/portage/pb/sys-apps/$pbpkg";
			pb_mkdir_p($tmpd) if (! -d "$tmpd");
			pb_mkdir_p("$ENV{'HOME'}/portage/distfiles") if (! -d "$ENV{'HOME'}/portage/distfiles");

			# We need to first extract the ebuild file 
			@ebuildfile = pb_extract_build_files($src,"$pbpkg-$pbver/pbconf/$ddir-$dver/","$tmpd");

			# Prepare the build env for gentoo
			my $found = 0;
			my $pbbd = $ENV{'HOME'};
			$pbbd =~ s|/|\\/|g;
			if (-r "/etc/make.conf") {
				open(MAKE,"/etc/make.conf");
				while (<MAKE>) {
					$found = 1 if (/$pbbd\/portage/);
				}
				close(MAKE);
			}
			if ($found == 0) {
				pb_system("sudo sh -c 'echo PORTDIR_OVERLAY=\"$ENV{'HOME'}/portage\" >> /etc/make.conf'");
			}
			#$found = 0;
			#if (-r "/etc/portage/package.keywords") {
			#open(KEYW,"/etc/portage/package.keywords");
			#while (<KEYW>) {
			#$found = 1 if (/portage\/pb/);
			#}
			#close(KEYW);
			#}
			#if ($found == 0) {
			#pb_system("sudo sh -c \"echo portage/pb >> /etc/portage/package.keywords\"");
			#}

			# Build
			foreach my $f (@ebuildfile) {
				if ($f =~ /\.ebuild$/) {
					move($f,"$tmpd/$pbpkg-$pbver.ebuild");
					pb_system("cd $tmpd ; ebuild $pbpkg-$pbver.ebuild clean ; ebuild $pbpkg-$pbver.ebuild digest ; ebuild $pbpkg-$pbver.ebuild package");
					# Now move it where pb expects it
					pb_mkdir_p("$ENV{'PBBUILDDIR'}/portage/pb/sys-apps/$pbpkg");
					move("$tmpd/$pbpkg-$pbver.ebuild","$ENV{'PBBUILDDIR'}/portage/pb/sys-apps/$pbpkg");
				}
			}

			$made="$made portage/pb/sys-apps/$pbpkg/$pbpkg-$pbver.ebuild";
		} elsif ($dtype eq "slackware") {
			$made="$made build-$pbpkg/$pbpkg-$pbver-*-$pbtag.tgz";
			pb_mkdir_p("$ENV{'PBBUILDDIR'}/install") if (! -d "$ENV{'PBBUILDDIR'}/install");
		} else {
			die "Unknown dtype format $dtype";
		}
	}
	# Keep track of what is generated so that we can get them back from VMs
	open(KEEP,"> $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to create $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
	print KEEP "$made\n";
	close(KEEP);
}

sub pb_build2ssh {
	pb_send2target("Sources");
}

sub pb_pkg2ssh {
	pb_send2target("Packages");
}

# By default deliver to the the public site hosting the 
# ftp structure (or whatever) or a VM/VE
sub pb_send2target {

	my $cmt = shift;
	my $v = shift || undef;
	my $vmexist = shift || 0;			# 0 is FALSE
	my $vmpid = shift || 0;				# 0 is FALSE

	my $host = "sshhost";
	my $login = "sshlogin";
	my $dir = "sshdir";
	my $port = "sshport";
	my $tmout = "sshtmout";
	my $path = "sshpath";
	my $conf = "sshconf";
	my $rebuild = "sshrebuild";
	if ($cmt eq "vm") {
		$login = "vmlogin";
		$dir = "pbdefdir";
		$tmout = "vmtmout";
		$rebuild = "vmrebuild";
		# Specific VM
		$host = "vmhost";
		$port = "vmport";
	} elsif ($cmt eq "ve") {
		$login = "velogin";
		$dir = "pbdefdir";
		$tmout = "vetmout";
		# Specific VE
		$path = "vepath";
		$conf = "veconf";
		$rebuild = "verebuild";
	}
	my $cmd = "";

	# Get list of packages to build
	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;

	# Get the running distro to consider
	my ($odir,$over,$oarch) = (undef, undef, undef);
	if (defined $v) {
		($odir,$over,$oarch) = split(/-/,$v);
	}
	my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init($odir,$over);
	pb_log(2,"DEBUG: distro tuple: ".join(',',($ddir, $dver, $dfam, $dtype, $pbsuf))."\n");

	# Get content saved in cms2build
	my ($pkg) = pb_conf_read("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
	$pkg = { } if (not defined $pkg);

	my $src = "";
	chdir "$ENV{'PBBUILDDIR'}";
	foreach my $pbpkg (@pkgs) {
		my $vertag = $pkg->{$pbpkg};
		# get the version of the current package - maybe different
		($pbver,$pbtag) = split(/-/,$vertag);

		if (($cmt eq "Sources") || ($cmt eq "vm") || ($cmt eq "ve")) {
			$src = "$src $ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz";
			if ($cmd eq "") {
				$cmd = "ln -sf $pbpkg-$pbver.tar.gz $pbpkg-latest.tar.gz";
			} else {
				$cmd = "$cmd ; ln -sf $pbpkg-$pbver.tar.gz $pbpkg-latest.tar.gz";
			}
		}
	}
	if (($cmt eq "vm") || ($cmt eq "ve")) {
		$src="$src $ENV{'PBDESTDIR'}/pbscript $ENV{'PBROOTDIR'}/$ENV{'PBPROJ'}.pb $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb $ENV{'PBETC'}";
	} elsif ($cmt eq "Script") {
		$src="$src $ENV{'PBDESTDIR'}/pbscript";
	} elsif ($cmt eq "Packages") {
		# Get package list from file made during build2pkg
		open(KEEP,"$ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to read $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		$src = <KEEP>;
		chomp($src);
		close(KEEP);
		if ($dtype eq "rpm") {
			# Also make a pbscript to generate yum/urpmi bases
			# $src = "$src $ENV{'PBDESTDIR'}/pbscript"
		} elsif ($dtype eq "deb") {
			# Also make a pbscript to generate apt bases
			# $src = "$src $ENV{'PBDESTDIR'}/pbscript"
		}
	}
	# Remove potential leading spaces (cause problem with basename)
	$src =~ s/^ *//;
	my $basesrc = "";
	foreach my $i (split(/ +/,$src)) {
		$basesrc .= " ".basename($i);
	}

	pb_log(0,"Sources handled ($cmt): $src\n");
	my ($sshhost,$sshlogin,$sshdir,$sshport,$vtmout,$vrebuild,$vepath,$veconf) = pb_conf_get($host,$login,$dir,$port,$tmout,$rebuild,$path,$conf);
	pb_log(2,"ssh: ".Dumper(($sshhost,$sshlogin,$sshdir,$sshport,$vtmout,$vrebuild,$vepath,$veconf))."\n");
	# Not mandatory
	my ($testver) = pb_conf_get_if("testver");

	my $mac;
	# Useless for VE
	if ($cmt ne "ve") {
		$mac = "$sshlogin->{$ENV{'PBPROJ'}}\@$sshhost->{$ENV{'PBPROJ'}}";
		# Overwrite account value if passed as parameter
		$mac = "$pbaccount\@$sshhost->{$ENV{'PBPROJ'}}" if (defined $pbaccount);
	}

	my $tdir;
	my $bdir;
	if (($cmt eq "Sources") || ($cmt eq "Script")) {
		$tdir = "$sshdir->{$ENV{'PBPROJ'}}/src";
	} elsif (($cmt eq "vm") || ($cmt eq "ve")) {
		$tdir = $sshdir->{$ENV{'PBPROJ'}}."/$ENV{'PBPROJ'}/delivery";
		$bdir = $sshdir->{$ENV{'PBPROJ'}}."/$ENV{'PBPROJ'}/build";
		# Remove a potential $ENV{'HOME'} as bdir should be relative to pb's home
		$bdir =~ s|\$ENV.+\}/||;
	} elsif ($cmt eq "Packages") {
		$tdir = "$sshdir->{$ENV{'PBPROJ'}}/$ddir/$dver";
		if ((defined $testver) && (defined $testver->{$ENV{'PBPROJ'}}) && ($testver->{$ENV{'PBPROJ'}} =~ /true/i)) {
			# This is a test pkg => target dir is under test
			$tdir .= "/test";
		}
	} else {
		return;
	}

	# Useless for VE
	my $nport;
	if ($cmt ne "ve") {
		$nport = $sshport->{$ENV{'PBPROJ'}};
		$nport = "$pbport" if (defined $pbport);
	}

	# Remove a potential $ENV{'HOME'} as tdir should be relative to pb's home
	$tdir =~ s|\$ENV.+\}/||;

	my $tm = $vtmout->{$ENV{'PBPROJ'}};

	# ssh communication if not VE
	my ($shcmd,$cpcmd,$cptarget,$cp2target);
	if ($cmt ne "ve") {
		my $keyfile = pb_ssh_get(0);
		$shcmd = "ssh -i $keyfile -q -p $nport $mac";
		$cpcmd = "scp -i $keyfile -p -P $nport";
		$cptarget = "$mac:$tdir";
		$cp2target = "$mac:$bdir";
	} else {
		my $tp = $vepath->{$ENV{'PBPROJ'}};
		$shcmd = "sudo chroot $tp/$v /bin/su - $sshlogin->{$ENV{'PBPROJ'}} -c ";
		$cpcmd = "cp -a ";
		$cptarget = "$tp/$tdir";
		$cp2target = "$tp/$bdir";
	}

	pb_system("$shcmd \"mkdir -p $tdir ; cd $tdir ; echo \'for i in $basesrc; do if [ -f \$i ]; then rm -f \$i; fi; done\ ; $cmd' | bash\"","Preparing $tdir on $cptarget");
	pb_system("cd $ENV{'PBBUILDDIR'} ; $cpcmd $src $cptarget 2> /dev/null","$cmt delivery in $cptarget");
	# For VE we need to change the owner manually - To be tested if needed
	#if ($cmt eq "ve") {
	#pb_system("cd $cptarget ; sudo chown -R $sshlogin->{$ENV{'PBPROJ'}} .","$cmt chown in $cptarget to $sshlogin->{$ENV{'PBPROJ'}}");
	#}
	pb_system("$shcmd \"echo \'cd $tdir ; if [ -f pbscript ]; then ./pbscript; fi\' | bash\"","Executing pbscript on $cptarget if needed");
	if (($cmt eq "vm") || ($cmt eq "ve")) {
		# Get back info on pkg produced, compute their name and get them from the VM
		pb_system("$cpcmd $cp2target/pbgen-$pbprojver-$pbprojtag $ENV{'PBBUILDDIR'} 2> /dev/null","Get package names in $cp2target");
		open(KEEP,"$ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to read $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		my $src = <KEEP>;
		chomp($src);
		close(KEEP);
		$src =~ s/^ *//;
		pb_mkdir_p("$ENV{'PBBUILDDIR'}/$odir/$over");
		# Change pgben to make the next send2target happy
		my $made = "";
		open(KEEP,"> $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to write $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		foreach my $p (split(/ +/,$src)) {
			my $j = basename($p);
			pb_system("$cpcmd $cp2target/\'$p\' $ENV{'PBBUILDDIR'}/$odir/$over 2> /dev/null","Package recovery of $j in $cp2target");
			$made="$made $odir/$over/$j" if (($dtype ne "rpm") || ($j !~ /.src.rpm$/));
		}
		print KEEP "$made\n";
		close(KEEP);
		pb_system("$shcmd \"rm -rf $tdir $bdir\"","$cmt cleanup");
		pb_send2target("Packages","$odir"."_"."$over");
		if ((! $vmexist) && ($cmt eq "vm")) {
			pb_system("$shcmd \"sudo /sbin/halt -p \"; sleep $tm ; echo \'if [ -d /proc/$vmpid ]; then kill -9 $vmpid; fi \' | bash ; sleep 10","VM $v halt (pid $vmpid)");
		}
		pb_rm_rf("$ENV{'PBBUILDDIR'}/$odir");
	}
}

sub pb_script2v {
	my $pbscript=shift;
	my $vtype=shift;

	# Prepare the script to be executed on the VM
	# in $ENV{'PBDESTDIR'}/pbscript
	if ((defined $pbscript ) && ($pbscript ne "$ENV{'PBDESTDIR'}/pbscript")) {
		copy($pbscript,"$ENV{'PBDESTDIR'}/pbscript") || die "Unable to create $ENV{'PBDESTDIR'}/pbscript";
		chmod 0755,"$ENV{'PBDESTDIR'}/pbscript";
	}

	my ($vm,$all) = pb_get_v($vtype);
	my ($vmexist,$vmpid) = (undef,undef);

	foreach my $v (@$vm) {
		# Launch the VM/VE
		if ($vtype eq "vm") {
			($vmexist,$vmpid) = pb_launchv($vtype,$v,0);

			# Skip that VM if something went wrong
			next if (($vmpid == 0) && ($vmexist ==0));
		}

		# Gather all required files to send them to the VM 
		# and launch the build through pbscript
		pb_send2target("Script","$v",$vmexist,$vmpid);

	}
}

sub pb_launchv {
	my $vtype = shift;
	my $v = shift;
	my $create = shift || 0;		# By default do not create a VM

	die "No VM/VE defined, unable to launch" if (not defined $v);
	# Keep only the first VM in case many were given
	$v =~ s/,.*//;

	# Which is our local arch ? (standardize on i386 for those platforms)
	my $arch = `uname -m`;
	chomp($arch);
	$arch =~ s/i.86/i386/;

	# Launch the VMs/VEs
	if ($vtype eq "vm") {
		die "-i iso parameter needed" if (((not defined $iso) || ($iso eq "")) && ($create != 0));

		my ($ptr,$vmopt,$vmport,$vmpath,$vmtmout,$vmsize) = pb_conf_get("vmtype","vmopt","vmport","vmpath","vmtmout","vmsize");

		my $vmtype = $ptr->{$ENV{'PBPROJ'}};
		if (not defined $ENV{'PBVMOPT'}) {
			$ENV{'PBVMOPT'} = "";
		}
		if (defined $vmopt->{$ENV{'PBPROJ'}}) {
			$ENV{'PBVMOPT'} .= " $vmopt->{$ENV{'PBPROJ'}}" if ($ENV{'PBVMOPT'} !~ / $vmopt->{$ENV{'PBPROJ'}}/);
		}
		my $nport = $vmport->{$ENV{'PBPROJ'}};
		$nport = "$pbport" if (defined $pbport);
	
		my $cmd;
		my $vmcmd;		# has to be used for pb_check_ps
		my $vmm;		# has to be used for pb_check_ps
		if ($vmtype eq "qemu") {
			my $qemucmd32;
			my $qemucmd64;
			if ($arch eq "x86_64") {
				$qemucmd32 = "/usr/bin/qemu-system-i386";
				$qemucmd64 = "/usr/bin/qemu";
			} else {
				$qemucmd32 = "/usr/bin/qemu";
				$qemucmd64 = "/usr/bin/qemu-system-x86_64";
			}
		if ($v =~ /x86_64/) {
				$vmcmd = "$qemucmd64 -no-kqemu";
			} else {
				$vmcmd = "$qemucmd32";
			}
			$vmm = "$vmpath->{$ENV{'PBPROJ'}}/$v.qemu";
			if ($create != 0) {
				$ENV{'PBVMOPT'} .= " -cdrom $iso -boot d";
			}
			$cmd = "$vmcmd $ENV{'PBVMOPT'} -redir tcp:$nport:10.0.2.15:22 $vmm"
		} elsif ($vmtype eq "xen") {
		} elsif ($vmtype eq "vmware") {
		} else {
			die "VM of type $vmtype not supported. Report to the dev team";
		}
		my ($tmpcmd,$void) = split(/ +/,$cmd);
		my $vmexist = pb_check_ps($tmpcmd,$vmm);
		my $vmpid = 0;
		if (! $vmexist) {
			if ($create != 0) {
				if (($vmtype eq "qemu") || ($vmtype eq "xen")) {
					pb_system("/usr/bin/qemu-img create -f qcow2 $vmm $vmsize->{$ENV{'PBPROJ'}}","Creating the QEMU VM");
				} elsif ($vmtype eq "vmware") {
				} else {
				}
			}
			if (! -f "$vmm") {
				pb_log(0,"Unable to find VM $vmm\n");
			} else {
				pb_system("$cmd &","Launching the VM $vmm");
				pb_system("sleep $vmtmout->{$ENV{'PBPROJ'}}","Waiting for VM $v to come up");
				$vmpid = pb_check_ps($tmpcmd,$vmm);
			}
		} else {
			pb_log(0,"Found an existing VM $vmm (pid $vmexist)\n");
		}
		return($vmexist,$vmpid);
	# VE here
	} else {
		# Get VE context
		my ($ptr,$vepath,$vetmout,$verebuild,$veconf) = pb_conf_get("vetype","vepath","vetmout","verebuild","veconf");
		my $vetype = $ptr->{$ENV{'PBPROJ'}};

		# Get distro context
		my ($name,$ver,$darch) = split(/-/,$v);
		chomp($darch);
		my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init($name,$ver);

		if ($vetype eq "chroot") {
			# Architecture consistency
			if ($arch ne $darch) {
				die "Unable to launch a VE of architecture $darch on a $arch platform" if (not (($darch eq "x86_64") && ($arch =~ /i?86/)));
			}

			if (($create != 0) || ($verebuild->{$ENV{'PBPROJ'}} eq "true") || ($force == 1)) {
				# We have to rebuild the chroot
				if ($dtype eq "rpm") {
					pb_system("sudo /usr/sbin/mock --init --resultdir=\"/tmp\" --configdir=\"$veconf->{$ENV{'PBPROJ'}}\" -r $v","Creating the mock VE");
					# Once setup we need to install some packages, the pb account, ...
					pb_system("sudo /usr/sbin/mock --install --configdir=\"$veconf->{$ENV{'PBPROJ'}}\" -r $v su","Configuring the mock VE");
					#pb_system("sudo /usr/sbin/mock --init --resultdir=\"/tmp\" --configdir=\"$veconf->{$ENV{'PBPROJ'}}\" --basedir=\"$vepath->{$ENV{'PBPROJ'}}\" -r $v","Creating the mock VE");
				} elsif ($dtype eq "deb") {
					pb_system("","Creating the pbuilder VE");
				} elsif ($dtype eq "ebuild") {
					die "Please teach the dev team how to build gentoo chroot";
				} else {
					die "Unknown distribution type $dtype. Report to dev team";
				}
			}
			# Nothing more to do for VE. No real launch
		} else {
			die "VE of type $vetype not supported. Report to the dev team";
		}
	}
}

sub pb_build2v {

my $vtype = shift;

# Prepare the script to be executed on the VM/VE
# in $ENV{'PBDESTDIR'}/pbscript
my ($ntp) = pb_conf_get($vtype."ntp");
my $vntp = $ntp->{$ENV{'PBPROJ'}};

open(SCRIPT,"> $ENV{'PBDESTDIR'}/pbscript") || die "Unable to create $ENV{'PBDESTDIR'}/pbscript";
print SCRIPT "#!/bin/bash\n";
print SCRIPT "echo ... Execution needed\n";
print SCRIPT "# This is in directory delivery\n";
print SCRIPT "# Setup the variables required for building\n";
print SCRIPT "export PBPROJ=$ENV{'PBPROJ'}\n";
print SCRIPT "# Preparation for pb\n";
print SCRIPT "mv .pbrc \$HOME\n";
print SCRIPT "cd ..\n";
# Force new date to be in the future compared to the date of the tar file by adding 1 minute
my @date=pb_get_date();
$date[1]++;
my $upddate = strftime("%m%d%H%M%Y", @date);
print SCRIPT "echo Setting up date on $vntp...\n";
# Or use ntpdate if available TBC
print SCRIPT "sudo date $upddate\n";
# This exports avoids pb_env_init to deal with PBCONF stuff
print SCRIPT "export PBCONF=/tmp\n";
print SCRIPT "export PBVER=$ENV{'PBVER'}\n";
print SCRIPT "export PBTAG=$ENV{'PBTAG'}\n";
print SCRIPT "export PBPACKAGER=\"$ENV{'PBPACKAGER'}\"\n";
print SCRIPT "# Build\n";
# Get list of packages to build
my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
@pkgs = @$ptr;
my $p = join(' ',@pkgs) if (@pkgs);
print SCRIPT "echo Building packages on $vtype...\n";
print SCRIPT "pb -p $ENV{'PBPROJ'} build2pkg $p\n";
close(SCRIPT);
chmod 0755,"$ENV{'PBDESTDIR'}/pbscript";

my ($v,$all) = pb_get_v($vtype);

# Send tar files when we do a global generation
pb_build2ssh() if ($all == 1);

my ($vmexist,$vmpid) = (undef,undef);

foreach my $v (@$v) {
	if ($vtype eq "vm") {
		# Launch the VM
		my ($vmexist,$vmpid) = pb_launchv($vtype,$v,0);

		# Skip that VM if it something went wrong
		next if (($vmpid == 0) && ($vmexist == 0));
	}
	# Gather all required files to send them to the VM/VE
	# and launch the build through pbscript
	pb_send2target($vtype,"$v",$vmexist,$vmpid);
}
}


sub pb_newver {

	die "-V Version parameter needed" if ((not defined $newver) || ($newver eq ""));

	my ($scheme,$uri)=pb_cms_init($pbinit);

	if ($scheme !~ /^svn/) {
		die "Only SVN is supported at the moment";
	}
	my $res = pb_cms_isdiff($scheme);
	die "You need to have no differences before creating a new version" if ($res != 0);
	my $cmsurl = pb_cms_getinfo($scheme,$ENV{'PBROOTDIR'},"URL:");
	my $newurl = dirname($cmsurl)."/$newver";
	pb_cms_copy($scheme,$cmsurl,$newurl);
	pb_cms_checkout($scheme,$newurl,"$ENV{'PBROOTDIR'}/../$newver");
	my $oldver=basename($cmsurl);
	open(FILE,"$ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb") || die "Unable to open $ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb";
	open(OUT,"> $ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new") || die "Unable to write to $ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new";
	while(<FILE>) {
		s/projver\s+$ENV{'PBPROJ'}\s*=\s*$oldver/projver $ENV{'PBPROJ'} = $newver/;
		print OUT $_;
	}
	close(FILE);
	close(OUT);
	rename("$ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new","$ENV{'PBROOTDIR'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb");
	pb_cms_checkin($scheme,"$ENV{'PBROOTDIR'}/../$newver");
}

#
# Return the list of VMs/VEs we are working on
# $all is a flag to know if we return all of them 
# or only some (if all we publish also tar files in addition to pkgs
#
sub pb_get_v {

my $vtype = shift;
my @v;
my $all = 0;
my $vlist;
my $pbv = 'PBV';

if ($vtype eq "vm") {
	$vlist = "vmlist";
} elsif ($vtype eq "ve") {
	$vlist = "velist";
}
# Get VM/VE list
if ((not defined $ENV{$pbv}) || ($ENV{$pbv} =~ /^all$/)) {
	my ($ptr) = pb_conf_get($vlist);
	$ENV{$pbv} = $ptr->{$ENV{'PBPROJ'}};
	$all = 1;
}
pb_log(2,"$vtype: $ENV{$pbv}\n");
@v = split(/,/,$ENV{$pbv});
return(\@v,$all);
}

# Function to create a potentialy missing pb account on the VM/VE, and adds it to sudo
# Needs to use root account to connect to the VM/VE
# pb will take your local public SSH key to access
# the pb account in the VM later on if needed
sub pb_setup_v {

my $vtype = shift;

# Script generated
my $pbscript = "$ENV{'PBDESTDIR'}/setupv";

# Name of the account to deal with for VM/VE
# Do not use the one passed potentially with -a
my $pbaccount = pb_conf_get($vtype."login");

if ($vtype eq "vm") {
	# Prepare the key to be used and transfered remotely
	my $keyfile = pb_ssh_get(1);
	
	my ($sshhost,$sshport) = pb_conf_get("vmhost","vmport");
	my $nport = $sshport->{$ENV{'PBPROJ'}};
	$nport = "$pbport" if (defined $pbport);

	pb_system("cat $keyfile.pub | ssh -q -p $nport -i $keyfile root\@$sshhost->{$ENV{'PBPROJ'}} \"mkdir .ssh ; chmod 700 .ssh ; cat > .ssh/authorized_keys ; chmod 600 .ssh/authorized_keys\"","Copying local keys to $vtype. This will require the root password");
	# once this is done, we can do what we want on the VM remotely
}

# Prepare the script to be executed on the VM/VE
# in $ENV{'PBDESTDIR'}/setupv

open(SCRIPT,"> $pbscript") || die "Unable to create $pbscript";
print SCRIPT << 'EOF';
#!/usr/bin/perl -w

use strict;
use File::Copy;

my $file="/etc/passwd";
open(PBFILE,$file) || die "Unable to open $file";
my $found = 0;
while (<PBFILE>) {
EOF
print SCRIPT << "EOF"
	\$found = 1 if (/^$pbaccount:/);
EOF
print SCRIPT << 'EOF';
}
close(PBFILE);

if ( $found == 0 ) {
	if ( ! -d "/home" ) {
		mkdir "/home";
	}
EOF
print SCRIPT << "EOF"
system "groupadd $pbaccount";
system "useradd $pbaccount -g $pbaccount -m -d /home/$pbaccount";

# For pb
chdir "/home/$pbaccount";
mkdir ".ssh",0700;
# Allow those accessing root to access the build account
copy("\$HOME/.ssh/authorized_keys",".ssh/authorized_keys");
chmod 0600,".ssh/authorized_keys";
system 'chown -R $pbaccount:$pbaccount .ssh';

EOF
print SCRIPT << 'EOF';
}

# No passwd for build account only keys
$file="/etc/shadow";
open(PBFILE,$file) || die "Unable to open $file";
open(PBOUT,"> $file.new") || die "Unable to open $file.new";
while (<PBFILE>) {
EOF
print SCRIPT << "EOF"
	s/^$pbaccount:\!\!:/$pbaccount:*:/;
	s/^$pbaccount:\!:/$pbaccount:*:/;	#SLES 9 e.g.
EOF
print SCRIPT << 'EOF'
	print PBOUT $_;
}
close(PBFILE);
close(PBOUT);
rename("$file.new",$file);
chmod 0640,$file;

# pb has to be added to portage group on gentoo

# Adapt sudoers
$file="/etc/sudoers";
open(PBFILE,$file) || die "Unable to open $file";
open(PBOUT,"> $file.new") || die "Unable to open $file.new";
while (<PBFILE>) {
EOF
print SCRIPT << "EOF"
	next if (/^$pbaccount   /);
EOF
print SCRIPT << 'EOF'
	s/Defaults[ \t]+requiretty//;
	print PBOUT $_;
}
close(PBFILE);
EOF
print SCRIPT << "EOF"
# This is needed in order to be able to halt the machine from the $pbaccount account at least
print PBOUT "$pbaccount   ALL=(ALL) NOPASSWD:ALL\n";
EOF
print SCRIPT << 'EOF'
close(PBOUT);
rename("$file.new",$file);
chmod 0440,$file;

EOF

pb_install_deps(SCRIPT);

print SCRIPT << 'EOF';
# Suse wants sudoers as 640
if (($ddir eq "sles") || (($ddir eq "suse")) && ($dver ne "10.3")) {
	chmod 0640,$file;
}

# Sync date
system "/usr/sbin/ntpdate ntp.pool.org";

system "rm -rf project-builder-* ; wget --passive-ftp ftp://ftp.mondorescue.org/src/project-builder-latest.tar.gz ; tar xvfz project-builder-latest.tar.gz ; cd project-builder-* ; perl Makefile.PL ; make ; make install ; cd ..";
EOF

# Adds pb_distro_init from Project-Builder::Distribution
foreach my $d (@INC) {
	my $f = "$d/Project-Builder/Distribution.pm";
	if (-f "$f") {
		open(PBD,"$f") || die "Unable to open $f";
		while (<PBD>) {
			print SCRIPT $_;
		}
		close(PBD);
		last;
	}
}
close(SCRIPT);
chmod 0755,"$pbscript";
return($pbscript);
}

sub pb_install_deps {

my \*SCRIPT = shift;

print SCRIPT << 'EOF';
# We need to have that pb_distro_init function
# Get it from Project-Builder::Distribution
my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init(); 
print "distro tuple: ".join(',',($ddir, $dver, $dfam, $dtype, $pbsuf))."\n";

# Get and install pb
if ( $ddir eq "fedora" ) {
	system "yum clean all";
	#system "yum update -y";
	my $arch=`uname -m`;
	my $opt = "";
	chomp($arch);
	if ($arch eq "x86_64") {
		$opt="--exclude=*.i?86";
	}

	system "yum -y $opt install rpm-build wget patch ntp sudo perl-DateManip perl-ExtUtils-MakeMaker";
} elsif (( $dfam eq "rh" ) || ($ddir eq "sles") || (($ddir eq "suse") && (($dver eq "10.1") || ($dver eq "10.0"))) || (($ddir eq "mandrake") && ($dver eq "10.1"))) {
	# Suppose pkg are installed already
	system "rpm -e lsb 2>&1 > /dev/null";
	system "rm -rf DateManip* ; wget http://search.cpan.org/CPAN/authors/id/S/SB/SBECK/Date-Manip-5.46.tar.gz ; tar xvfz Date-Manip-5.46.tar.gz ; cd Date-Manip* ; perl Makefile.PL ; make ; make install ; cd .. ";
} elsif ($ddir eq "suse") { 
	# New OpenSuSE
	system "export TERM=linux ; liste=\"\" ; for i in make wget patch sudo perl-DateManip perl-File-HomeDir xntp; do rpm -q \$i 1> /dev/null 2> /dev/null ; if [ \$\? != 0 ]; then liste=\"\$liste \$i\"; fi; done; echo \"Liste: \$liste\" ; if [ \"\$liste\" != \"\" ]; then yast2 -i \$liste ; fi";
} elsif ( $dfam eq "md" ) {
		system "urpmi.update -a ; urpmi --auto rpm-build wget sudo patch ntp-client perl-DateManip";
} elsif ( $dfam eq "du" ) {
	if (( $dver eq "3.1" ) && ($ddir eq "debian")) {
		#system "apt-get update";
		system "apt-get -y install wget patch ssh sudo debian-builder dh-make fakeroot ntpdate libdate-manip-perl";
	} else  {
		system "apt-get update; apt-get -y install wget patch openssh-server dpkg-dev sudo debian-builder dh-make fakeroot ntpdate rses5-dev libdate-manip-perl";
	}
} elsif ( $dfam eq "gen" ) {
		system "emerge -u system ; emerge wget sudo ntp DateManip";
} else {
	print "No pkg to install\n";
}
EOF
}

# Return the SSH key file to use
# Potentially create it if needed

sub pb_ssh_get {

my $create = shift || 0;	# Do not create keys by default

# Check the SSH environment
my $keyfile = undef;

# We have specific keys by default
$keyfile = "$ENV{'HOME'}/.ssh/pb_dsa";
if ((-s $keyfile) && ($create eq 1)) {
	pb_system("ssh-keygen -q -b 1024 -N '' -f $keyfile -t dsa","Generating SSH keys for pb");
}

$keyfile = "$ENV{'HOME'}/.ssh/id_rsa" if (-s "$ENV{'HOME'}/.ssh/id_rsa");
$keyfile = "$ENV{'HOME'}/.ssh/id_dsa" if (-s "$ENV{'HOME'}/.ssh/id_dsa");
$keyfile = "$ENV{'HOME'}/.ssh/pb_dsa" if (-s "$ENV{'HOME'}/.ssh/pb_dsa");
die "Unable to find your public ssh key under $keyfile" if (not defined $keyfile);
return($keyfile);
}


# Returns the pid of a running VM command using a specific VM file
sub pb_check_ps {
	my $vmcmd = shift;
	my $vmm = shift;
	my $vmexist = 0;		# FALSE by default

	open(PS, "ps auxhww|") || die "Unable to call ps";
	while (<PS>) {
		next if (! /$vmcmd/);
		next if (! /$vmm/);
		my ($void1, $void2);
		($void1, $vmexist, $void2) = split(/ +/);
		last;
	}
	return($vmexist);
}


sub pb_extract_build_files {

my $src=shift;
my $dir=shift;
my $ddir=shift;
my @files;

if ($src =~ /tar\.gz$/) {
	pb_system("tar xfpz $src $dir","Extracting build files");
} elsif ($src =~ /tar\.bz2$/) {
	pb_system("tar xfpj $src $dir","Extracting build files");
} else {
	die "Unknown compression algorithm for $src";
}
opendir(DIR,"$dir") || die "Unable to open directory $dir";
foreach my $f (readdir(DIR)) {
	next if ($f =~ /^\./);
	move("$dir/$f","$ddir") || die "Unable to move $dir/$f to $ddir";
	pb_log(2,"mv $dir/$f $ddir\n");
	push @files,"$ddir/$f";
}
closedir(DIR);
# Not enough but still a first cleanup
pb_rm_rf("$dir");
return(@files);
}

sub pb_list_bfiles {

my $dir = shift;
my $pbpkg = shift;
my $bfiles = shift;
my $pkgfiles = shift;
my $supfiles = shift;

opendir(BDIR,"$dir") || die "Unable to open dir $dir: $!";
foreach my $f (readdir(BDIR)) {
	next if ($f =~ /^\./);
	$bfiles->{$f} = "$dir/$f";
	$bfiles->{$f} =~ s~$ENV{'PBROOTDIR'}~~;
	if (defined $supfiles->{$pbpkg}) {
		$pkgfiles->{$f} = "$dir/$f" if ($f =~ /$supfiles->{$pbpkg}/);
	}
}
closedir(BDIR);
}

sub pb_syntax {

my $exit_status = shift || -1;
my $verbose_level = shift || 0;

my $filehandle = \*STDERR;

$filehandle = \*STDOUT if ($exit_status == 0);

pod2usage( { -message => "pb (aka project-builder.org) Version $projectbuilderver-$projectbuilderrev\n",
             -exitval => $exit_status  ,
             -verbose => $verbose_level,
             -output  => $filehandle } );
}