source: projects/md2mb/devel/md2mb/bin/md2mb.pl @ 1453

Last change on this file since 1453 was 1453, checked in by ebaudrez, 7 years ago

rectify a mistake concerning formail/procmail

The program erroneously assumed that either formail or procmail could be
used (this mistake was introduced by EB in an earlier commit).
Rectifying the situation: we use formail, but suggest to install the
package procmail on those systems where the formail utility is contained
in the procmail package.

File size: 9.6 KB
Line 
1#!/usr/bin/perl -w
2
3=head1 NAME
4
5md2mb.pl - Import a maildir kmail environment into a thunderbird one
6
7=cut
8
9use strict;
10use File::Find;
11use File::Copy;
12use File::Basename;
13use File::Path;
14use File::Glob ':glob';
15use Getopt::Long;
16use Pod::Usage;
17use List::Util qw(first);
18
19# settings
20my $cmd = 'formail';
21my $debug = 0;
22my $file = 0; # is the newroot a file (1) or a dir (0) ?
23my $help = 0;
24my $man = 0;
25my $oldroot = first { -d } "$ENV{HOME}/.Mail", "$ENV{HOME}/Mail";
26my @default_profiles = bsd_glob("$ENV{HOME}/.thunderbird/*.default");
27my $profile = shift @default_profiles;
28# if there is more than one default profile (quite unlikely, but you never
29# know), unset $profile again and let the user resolve this
30if (@default_profiles) { undef $profile }
31my $subdir;
32my $touch = 0;
33
34# parse command-line options
35GetOptions(
36    'cmd|c'           => \$cmd,
37    'debug|d'         => \$debug,
38    'file|f'          => \$file,
39    'help|h'          => \$help,
40    'man|m'           => \$man,
41    'oldroot|old|o=s' => \$oldroot,
42    'profile|p=s'     => \$profile,
43    'subdir|s=s'      => \$subdir,
44    'touch|t'         => \$touch,
45) or pod2usage(2);
46pod2usage(1) if ($help);
47pod2usage(-exitstatus => 0, -verbose => 2) if ($man);
48defined $subdir or pod2usage("Error: -subdir is a mandatory argument\n");
49
50# the new root is constructed from the profile and the chosen subdirectory name
51my $newroot = "$profile/$subdir";
52
53# debug mode overview
54if ($debug) {
55    print <<EOF;
56DEBUG MODE, not doing anything, just printing
57--- current state ---
58cmd     = $cmd
59oldroot = $oldroot
60profile = $profile
61subdir  = $subdir
62newroot = $newroot (constructed)
63--- end ---
64EOF
65}
66
67# some sanity checks before proceeding
68system("$cmd </dev/null >/dev/null 2>/dev/null") == 0 or die <<EOF;
69Cannot run `$cmd' or locate it in your \$PATH!
70
71I need the program `formail' to process your mailboxes. You can provide the
72full path to the formail utility using the `-cmd' command-line switch.
73
74Perhaps `formail' is not installed on your system. Try installing the `formail'
75package using your distribution's package manager. The formail utility might be
76contained in the `procmail' package (e.g., Ubuntu 11.10), so you may need to
77look for the latter instead.
78
79Aborting ...
80EOF
81-d $oldroot or die "cannot find mailbox root `$oldroot'";
82-d $profile or die "cannot find Thunderbird profile directory `$profile'";
83
84# create destination path
85if ($debug) { 
86    print "TARGET DIR: mkdir -p $newroot\n" if ((not -d "$newroot") && (not $file));
87    print "CMD: mkdir -p $newroot\n" if ((not -d "$newroot") && (not $file));
88} else {
89    mkpath("$newroot",0, 0755) if ((not -d "$newroot") && (not $file));
90}
91
92# the main work is done here
93if ($debug) {
94    print "DESCENDING INTO oldroot($oldroot)\n";
95}
96find(\&md2mb,($oldroot));
97
98# now go back again and create empty files corresponding to the `.sbd'
99# directories
100if ($touch) {
101    print "DESCENDING AGAIN INTO oldroot($oldroot)\n" if ($debug);
102    find(sub {
103            return if (! -d);   # consider only directories ...
104            return if (! /\.sbd$/); # ... with the right name
105            s/\.sbd//;      # strip .sbd suffix
106            if ($debug) {
107                print "WOULD CREATE file($_) IF NEEDED\n";
108            } else {
109                open my $fh, '>>', $_ or die "cannot open $_: $!";
110            }
111        }, $newroot);
112}
113
114# rename `inbox' to `Inbox'
115if ((-z "$newroot/Inbox") || (! -e "$newroot/Inbox")) {
116    if ($debug) {
117        print "RENAMING inbox($newroot/inbox) INTO Inbox($newroot/Inbox)\n" if (-e "$newroot/inbox");
118    } else {
119        print "Renaming inbox into Inbox\n";
120        move("$newroot/inbox","$newroot/Inbox") if (-e "$newroot/inbox");
121    }
122}
123
124sub md2mb {
125
126if (-f $File::Find::name) {
127    if (($File::Find::name =~ /\.ids$/) ||
128        ($File::Find::name =~ /\.sorted$/) ||
129        ($File::Find::name =~ /\.index$/)) {
130        print "SKIP FILE: $File::Find::name\n" if ($debug);
131        return;
132    }
133}
134if (-d $File::Find::name) {
135    if (($File::Find::name =~ /\/cur$/) ||
136        ($File::Find::name =~ /\/new$/) ||
137        ($File::Find::name =~ /\/tmp$/)) {
138        print "SKIP DIR: $File::Find::name\n" if ($debug);
139        return;
140    }
141}
142my $destname = $File::Find::name;
143# Target name is under a different root dir
144$destname =~ s|^$oldroot||;
145# Target name is not under a .directory dir but under a .sdb one
146$destname =~ s|\.([^/]+)\.directory/|$1.sbd/|g;
147# Here we create the target dir and target name
148my $outputfile="$newroot/$destname";
149my $cdir = dirname("$outputfile");
150# Handle case where target file name is empty
151$outputfile="$newroot" if ($destname =~ /^\s*$/);
152# When we treat a dir, we will have to handle what it has below
153if (-d $File::Find::name) {
154    if ($debug) { 
155        print "DIR SRC: $File::Find::name\n";
156    }
157    my @files = (bsd_glob("$File::Find::name/cur/*"),bsd_glob("$File::Find::name/new/*"));
158    if (@files) {
159        if ($debug) { 
160            print "DIR ($File::Find::name) DIR TARGET: mkdir -p $cdir\n" if (not -d "$cdir");
161        } else {
162            mkpath("$cdir",0, 0755) if (not -d "$cdir");
163        }
164    }
165    foreach my $file (@files) {
166        next unless -f $file; # skip non-regular files
167        next unless -s $file; # skip empty files
168        next unless -r $file; # skip unreadable files
169        $file =~ s/'/'"'"'/g;  # escape ' (single quote)
170        # NOTE! The output file must not contain single quotes (')!
171        my $run = "cat '$file' | $cmd >> '$outputfile'";
172        if ($debug) { 
173            print "COPYING CONTENT maildir($file) to $outputfile\n";
174            print "CMD: $run\n";
175        } else {
176            print "Copying maildir content from $file to $outputfile\n";
177            system($run) == 0 or warn "cannot run \"$run\".";
178        }
179    }
180}
181if (-f $File::Find::name) {
182    if (($File::Find::name =~ /\/cur\//) ||
183        ($File::Find::name =~ /\/new\//) ||
184        ($File::Find::name =~ /\/tmp\//)) {
185        print "SKIP FILE: $File::Find::name\n" if ($debug);
186        return;
187    }
188    if ($debug) { 
189        print "FILE ($File::Find::name) TARGET DIR: mkdir -p $cdir\n" if (not -d "$cdir");
190        print "CMD: cp $File::Find::name $cdir\n";
191    } else {
192        print "Copying mailbox content from $File::Find::name to $cdir\n";
193        mkpath("$cdir",0, 0755) if (not -d "$cdir");
194        copy($File::Find::name,$cdir);
195    }
196}
197}
198__END__
199
200=head1 SYNOPSIS
201
202md2mb.pl  [options]  -s name
203
204 Options:
205   -cmd     | -c                command to process mail
206   -debug   | -d        debug mode
207   -file    | -f                whether $newroot is a file or a directory
208   -help    | -h        brief help message
209   -man     | -m        full documentation
210   -oldroot | -old | -o     location of the KMail mailboxes
211   -profile | -p        path to the Thunderbird profile to install to
212   -subdir  | -s        subdir that will be created to hold the
213                imported mails
214   -touch   | -t        create empty files corresponding to .sdb dirs
215
216=head1 OPTIONS
217
218=over 4
219
220=item B<-cmd>
221
222Specify the command to process your maildirs. By default uses B<formail> in
223your C<$PATH>, but you can use this option to specify the full path to the
224executable to use instead.
225
226=item B<-debug>
227
228Enter debug mode. This will print what would be done. No commands are executed,
229so this is safe to use when testing.
230
231=item B<-file>
232
233Specifies that $newroot is a file. If this option is omitted, it is assumed
234that $newroot is a directory instead.
235
236=item B<-help>
237
238Print a brief help message and exits.
239
240=item B<-man>
241
242Prints the manual page and exits.
243
244=item B<-oldroot> I<path>
245
246Specify where your B<KMail> mailboxes are to be found. By default assumes a
247folder called F<.Mail> or F<Mail> in your homedir, preferring F<.Mail> if it
248exists.
249
250=item B<-profile> I<path>
251
252Specify the path to the Thunderbird profile. Your imported mails will go inside
253a directory in this profile. By default uses the default profile in the
254F<.thunderbird> directory in your home directory, if it is unique.
255
256=item B<-subdir> I<name>
257
258Specify the subdirectory I<name> that will be created inside the Thunderbird
259profile to hold the imported mails. This option is mandatory; there is no
260default.
261
262=item B<-touch>
263
264Create empty files corresponding to the F<.sbd> dirs created by this script.
265Use this hack if your mails don't show up in Thunderbird.
266
267=back
268
269=head1 EXAMPLES
270
271    # this will fetch all mails from the folder .Mail or Mail in your home
272    # directory, and import them into your default Thunderbird profile, in
273    # a directory called Mail/pop.home.musique-ancienne.org/
274    #
275    # usually, this is all you need to specify:
276
277    perl md2mb.pl -s Mail/pop.home.musique-ancienne.org/
278
279    # on your computer, the mails may end up in
280    # /users/segolene/.thunderbird/qk2f4dl6.default/Mail/pop.home.musique-ancienne.org/
281
282    # if md2mb.pl cannot figure out where your default Thunderbird profile
283    # is, use the following:
284
285    perl md2mb.pl -p ~/.thunderbird/qk2f4dl6.default -s Mail/pop.home.musique-ancienne.org/
286
287=head1 DESCRIPTION
288
289B<md2mb.pl> will import a B<kmail> maildir environment, and transform it into a
290B<thunderbird> one. It relies on B<formail> (or an equivalent utility) being
291available on your system.
292
293By default, B<md2mb.pl> assumes that your B<kmail> mailboxes are stored in a
294folder called F<.Mail> or F<Mail> in your homedir. If this assumption is
295incorrect, you need to specify the correct folder with B<-oldroot>.
296
297The mails will be imported into the Thunderbird profile that is either
298specified with B<-profile> or determined automatically. The script will try to
299determine the default Thunderbird profile automatically. If there is a folder
300that ends in F<.default> in the F<.thunderbird> directory in your home dir, and
301if it is unique, that one will be used.
302
303The mails finally end up in a subdirectory below the profile. You must specify
304the subdirectory on the command line with B<-subdir>, as shown in the examples
305above.
306
307If you have used a structure with subfolders in KMail, mails in subfolders
308might not show up in Thunderbird. Remove the import, and run again with
309B<-touch>.
310
311=head1 AUTHOR
312
313=over 4
314
315=item *
316
317Bruno Cornec, http://brunocornec.wordpress.com
318
319=item *
320
321Edward Baudrez, C<< ebaudrez@cpan.org >>
322
323=back
324
325=head1 LICENSE
326
327Released under the GPLv2 or the Artistic license at your will.
328
329=cut
Note: See TracBrowser for help on using the repository browser.