#!/usr/bin/perl -w
#
=head1 NAME

cb - CasparBuster looks at the structure in your CMS environment and deploy it to the target systems as needed

=head1 SYNOPSIS

cb [options]

 Options:
   --debug  |-d			debug mode
   --help   |-h			brief help message
   --man			full documentation
   --force  |-f			force copy of files, even if they exist
   --source |-s <file/dir>	directory or files to copy from the CasparBuster tree (',' separated if many) to the target
   --plugin |-p <plugin name>	plugin defining what to copy from the CasparBuster tree (',' separated if many) to the target
   --machine|-m <machine>	machine to deploy on.

=head1 OPTIONS

=over 4

=item B<--debug>

Enter debug mode. This will print what would be done. No commands are executed,
so this is safe to use when testing.

=item B<--help>

Print a brief help message and exits.

=item B<--man>

Prints the manual page and exits.

=item B<--machine> I<machine name>

Specify the machine to consider when dealing with the CasparBuster structure. 
The files will be pushed to this machine, and a subdirectory named after the machine 
will be used under the basedir to look at the directory structure to deploy

=item B<--source> I<path>

Specify the path of the source file or directory to deploy with CasparBuster. Multiple paths can be specified separated by ','.

=item B<--plugin> I<name>

Specify the name of the plugin to deploy with CasparBuster. Multiple plugins can be specified separated by ','.
A plugin defines a set of files (with their mode and owner), a set of directories (with their mode and owner) and a set of scripts to launch once the files are copied remotely.

=back

=head1 DESCRIPTION

Deploy the standard CasparBuster structure created by I<cbusterize>. It will reinstall all files and directory in the plugin, with correct owner, group and mode, and launch at the end the script to re-enable potentially the service using the updated files.

=head1 EXAMPLES

	# this will deploy the appropriate CasparBuster environment for DHCP
	# from the base ~/prj/musique-ancienne.org directory (Cf cbbasedir in cb.conf)
	# containing the directory victoria2 for this machine
	# to which it will copy the required files

	cb -m victoria2 -p dhcpd

=head1 AUTHOR

=over 4

Bruno Cornec, http://brunocornec.wordpress.com

=back

=head1 LICENSE

Copyright (C) 2012  Bruno Cornec <bruno@project-builder.org>
Released under the GPLv2 or the Artistic license at your will.

=cut
use strict;
use CasparBuster::Version;
use CasparBuster::Env;
use CasparBuster::Plugin;
#use Cwd 'realpath';
use File::Find;
use Archive::Tar;
use Getopt::Long;
use Pod::Usage;
use Data::Dumper;
use Time::Local;
use Net::SSH2;
use ProjectBuilder::Base;
use ProjectBuilder::Conf;
use ProjectBuilder::VCS;
use DBI;
use DBD::SQLite;

# settings
my $debug = 0;
my $help = undef;
my $man = undef;
my $source = undef;
my $machine = undef;
my $plugin = undef;
my $quiet = undef;
my $force = undef;
my $log = undef;
my $LOG = undef;

my ($cbver,$cbrev) = cb_version_init();
my $appname = "cb";
$ENV{'PBPROJ'} = $appname;
pb_temp_init();

# Initialize the syntax string
pb_syntax_init("$appname (aka CasparBuster) Version $cbver-$cbrev\n");

# parse command-line options
GetOptions(
	'machine|m=s' => \$machine,
	'debug|d+'    => \$debug,
	'help|h'      => \$help,
	'quiet|q'     => \$quiet,
	'force|f'     => \$force,
	'man'         => \$man,
	'logfile|l=s' => \$log,
	'source|s=s'  => \$source,
	'plugin|p=s'  => \$plugin,
) || pb_syntax(-1,0);

if (defined $help) {
	pb_syntax(0,1);
}
if (defined $man) {
	pb_syntax(0,2);
}
if (defined $quiet) {
	$debug=-1;
}
if (defined $log) {
	open(LOG,"> $log") || die "Unable to log to $log: $!";
	$LOG = \*LOG;
	$debug = 0  if ($debug == -1);
}

$pbdebug = $debug;
pb_log_init($debug, $LOG);
pb_log(0,"Starting cb\n");

# Get conf file in context
pb_conf_init($appname);
# The personal one if there is such
pb_conf_add("$ENV{'HOME'}/.cbrc") if (-f "$ENV{'HOME'}/.cbrc");
# The system one
pb_conf_add(cb_env_conffile());

# Get configuration parameters
my %cb;
my $cbp = ();
my $cb = \%cb;
($cb->{'basedir'},$cb->{'usemachines'},$cb->{'cms'},$cb->{'database'}) = pb_conf_get("cbbasedir","cbusemachines","cbcms","cbdatabase");
pb_log(2,"%cb: ",Dumper($cb));

die "No machine should be given when using machine structure" if (($cb->{'usemachines'}->{$appname} !~ /true/) && (defined $machine));

if (defined $plugin) {
	# Load plugins
	cb_plugin_load();
}

my $basedir = $cb->{'basedir'}->{$appname};
eval { $basedir =~ s/(\$ENV.+\})/$1/eeg };

# Create basedir if it doesn't exist
die "Unable to find base directory at $basedir" if (not -d $basedir);

pb_log(1, "DEBUG MODE, not doing anything, just printing\nDEBUG: basedir = $basedir\n");

# Create database if not existing and give a handler
my $db = "$basedir/$cb->{'database'}->{$appname}";

my $precmd = "";
if (! -f $db) {
	$precmd = "CREATE TABLE dates (id INTEGER PRIMARY KEY AUTOINCREMENT, date INTEGER, file VARCHAR[65535], machine VARCHAR[65535])";
}

my $dbh = DBI->connect("dbi:SQLite:dbname=$db","","",
			{ RaiseError => 1, AutoCommit => 1 })
			|| die "Unable to connect to $db";
my $sth;

if ($precmd ne "") {
	$sth = $dbh->prepare(qq{$precmd}) || die "Unable to create table into $db";
	if ($debug) {
		pb_log(1,"DEBUG: Creating DB $db\n");
		pb_log(1,"DEBUG: with command $precmd\n");
	} else {
		$sth->execute();
	}
	$sth->finish();
}

# Define destination dir and populate with a VCS export
my $dest = "$ENV{'TMPDIR'}/vcs.$$";
my $scheme = $cb->{'cms'}->{$appname};
pb_vcs_export(pb_vcs_get_uri($scheme,$basedir),$basedir,$dest);

# Now distribute to the right machines
if (defined $machine) {
	cb_distribute($machine);
} else {
	if ($cb->{'usemachines'}->{$appname} =~ /true/) {
		# First dir level is the machine, then the content
		opendir(DIR,$dest) || die "Unable to open $dest: $!";
		foreach my $m (readdir(DIR)) {
			next if ($m =~ /^\./);
			next if (! -d $m);
			# Machine name
			cb_distribute($m);
		}
		closedir(DIR);
	} else {
		cb_distribute(undef);
	}
}

# Cleanup
if (not $debug) {
	pb_rm_rf($dest);
} else {
	pb_log(0,"DEBUG: Please remove manually with rm -rf $dest\n")
}
$dbh->disconnect;

# End of Main

# Distribute files to target machines
sub cb_distribute {

my $machine = shift;

pb_log(2,"Entering into cb_distribute with machine $machine\n");

# Use potentially a remote account if defined
my $remote = undef;
my ($account) = pb_conf_get_if("cbaccount") if (defined $machine);
$remote = $account->{$machine} if ((defined $account) && (defined $machine) && (defined $account->{$machine}));
pb_log(1, "DEBUG: remote account1 = $remote\n") if (defined $remote);
$remote = getpwuid($<) if (not defined $remote);
pb_log(1, "DEBUG: remote account2 = $remote\n");

# Now handle plugins if any
if (defined $plugin) {
	foreach my $p (split(/,/,$plugin)) {	
		pb_log(1,"Getting context for plugin $p\n");
		$cbp = cb_plugin_get($p,$cbp);
		# Adds mtime info to the plugin structure
		foreach my $type ('files','dirs','dirsandfiles') {
			foreach my $f (keys %{$cbp->{$p}->{$type}}) {
				my $tdir = $dest;
				if (defined $machine) {
					$tdir = "$dest/$machine";
				}
				if (-r "$tdir/$f") {
					my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,$atime,$mtime,$ctime,$blksize,$blocks) = stat("$tdir/$f") || die "Unable to stat $tdir: $!";
					$cbp->{$p}->{$type}->{$f}->{'mtime'} = $mtime;
				} else {
					pb_log(0,"WARNING: Unable to read $tdir/$f from plugin $p\n");
				}	
			}
		}
	}
}

# Handle this source
if (defined $source) {
	my $fullsource = "$source";
	$fullsource = "$machine/$source" if (defined $machine);
	pb_log(2,"fullsource is $fullsource\n");
	my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,$atime,$mtime,$ctime,$blksize,$blocks) = stat("$dest/$fullsource") || die "Unable to stat $fullsource: $!";
	my $type = 'files';
	if (-d $fullsource) {
		$type = 'dirsandfiles';
	}
	die "ERROR: Only able to handle files or dirs with option --source\n" if ((! -d $fullsource) && (! -f $fullsource));

 	$cbp->{"cb.source"}->{$type}->{$source}->{'uid'} = $uid;
	$cbp->{"cb.source"}->{$type}->{$source}->{'gid'} = $gid;
	$cbp->{"cb.source"}->{$type}->{$source}->{'mode'} = $mode;
	$cbp->{"cb.source"}->{$type}->{$source}->{'mtime'} = $mtime;
}

if ((not defined $source) && (not defined $plugin)) {
	# Here we need to take all content under $dest considering that machine
	if (defined $machine) {
		find(\&cb_add_to_cbp,("$dest/$machine"));
	} else {
		find(\&cb_add_to_cbp,($dest));
	}
}
pb_log(2,"INFO: RAW cbp: ".Dumper(%$cbp)."\n");

# Clean up cbp structure by comparing with data stored in the DB
# Only keep the more recent modified content
my $mac = $machine;
$mac = "localhost" if (not defined $machine);
# Allow for errors to occur at DBI level
$dbh->{RaiseError} = 0;
my $checkdb = 1;
my $dbcmd = "SELECT id,date,file,machine FROM dates WHERE machine=\"$mac\"";
if (! ($sth = $dbh->prepare(qq{$dbcmd}))) {
		pb_log(0,"Unable to prepare DB statement $dbcmd\n");
		$checkdb = 0;
}
# DisAllow for errors to occur at DBI level
$dbh->{RaiseError} = 1;
my $dbid = ();
if ($checkdb == 1) {
	$sth->execute();
	# Check what in cbp is in the DB and deploy only if necessary
	foreach my $k (keys %{$cbp}) {
		foreach my $type ('files','dirs','dirsandfiles') {
			foreach my $o (keys %{$cbp->{$k}->{$type}}) {
				# Compare with info from DB
				foreach my $row ($sth->fetch) {
					next if (not defined $row);
					my ($id, $date, $file, $mac1) = @$row;
					# If less recent than in the DB remove it
					$cbp->{$k}->{$type}->{$o}->{'deleted'} = "true" if ((defined $file) && ($file eq $o) && ($date > $cbp->{$k}->{$type}->{$o}->{'mtime'}));
					$dbid->{$o} = $id;
				}
			}
		}
	}
	$sth->finish();
}
pb_log(2,"INFO: cleaned cbp: ".Dumper($cbp)."\n");

# Now create a tar containing all the relevant content
# We need to loop separately to allow for DB to not exist in the previous loop !
my $tdir = undef;
if (defined $machine) {
	$tdir = "$dest/$machine";
} else {
	$tdir = "$dest";
}
chdir("$tdir") || die "ERROR: Unable to chdir to $tdir\n";
pb_log(2,"Working now under $tdir\n");

my $tar = Archive::Tar->new;
$tar->setcwd($tdir);
my $curdate = time();
foreach my $k (keys %{$cbp}) {
	foreach my $type ('files','dirs','dirsandfiles') {
		# TODO: for dirs we may remove the files below ?
		foreach my $o ((keys %{$cbp->{$k}->{$type}})) {
			if (not defined $cbp->{$k}->{$type}->{$o}->{'deleted'}) {
				$tar->add_files("./$o");
				# Add an entry to the DB
				if (defined $dbid->{$o}) {
					# Modify an existing entry
					$dbcmd = "UPDATE dates SET date=$curdate,file=$o WHERE id='?'";
					if (not $debug) {
						$sth = $dbh->prepare(qq{$dbcmd});
						$sth = $dbh->execute($dbid->{$o});
					} else {
						pb_log(0,"Executing in DB: $dbcmd with curdate=$curdate,file=$o,id=$dbid->{$o}\n");
					}
		 		} else {
					# Add an new entry
					$dbcmd = "INSERT INTO dates VALUES (NULL,?,?,$mac)";
					if (not $debug) {
						$sth = $dbh->prepare(qq{$dbcmd});
						$sth = $dbh->execute($curdate,$o);
					} else {
						pb_log(0,"Executing in DB: $dbcmd with curdate=$curdate,file=$o,machine=$mac\n");
					}
		 		}
				if (not $debug) {
					$sth->finish();
				}
			}
		}
	}
}
my $tarfile = "$ENV{'TMPDIR'}/cbcontent$$.tar";
$tar->write("$tarfile");

my $ssh2;
my $chan;

# deal with content first
if (defined $machine) {
	# Create remote connection and copy tar file there
	$ssh2 = Net::SSH2->new();
	$ssh2->connect($machine);
	my $hdir = (getpwnam(getpwuid($<)))[7];
	if ($ssh2->auth_publickey($remote,"$hdir/.ssh/id_dsa.pub","$hdir/.ssh/id_dsa")) {
		$chan = $ssh2->channel();
		if (not $debug) {
			$chan->exec("if [ ! -d $ENV{'TMPDIR'} ]; then mkdir -p $ENV{'TMPDIR'} fi");
			$ssh2->scp_put($tarfile,$ENV{'TMPDIR'});
			#$chan->exec("cd / ; tar xf $tarfile");
		} else {
			pb_log(1,"INFO: creating $ENV{'TMPDIR'} if needed on $remote\@$machine and copying content\n");
		}
	} else {
		pb_log(0,"ERROR: Unable to authenticate to $remote\@$machine\n");
		return;
	}
}

# Pointer to function depending whether we're local or remote
my $func;
if (defined $machine) {
	$func = \&{ $chan->exec };
} else {
	$func = \&pb_system;
}

if (not $debug) {
	&$func("cd / ; tar xf $tarfile");
} else {
	pb_log(1,"INFO: Extracting (on $mac) $tarfile under /\n");
}

foreach my $k (keys %{$cbp}) {
	foreach my $type ('files','dirs','dirsandfiles') {
		# TODO: do we act recursively for dirsandfiles at least for uid/gid ?
		foreach my $o ((keys %{$cbp->{$k}->{$type}})) {
			if (not defined $cbp->{$k}->{$type}->{$o}->{'deleted'}) {
				if ($debug) {
					pb_log(1,"INFO: Executing (on $mac) sudo chown $cbp->{$k}->{$type}->{$o}->{'uid'}:$cbp->{$k}->{$type}->{$o}->{'gid'} $o\n");
					pb_log(1,"INFO: Executing (on $mac) sudo chmod $cbp->{$k}->{$type}->{$o}->{'mode'} $o\n");
				} else {
					&$func("sudo chown $cbp->{$k}->{$type}->{$o}->{'uid'}:$cbp->{$k}->{$type}->{$o}->{'gid'} $o");
					&$func("sudo chmod $cbp->{$k}->{$type}->{$o}->{'mode'} $o");
				}
			}
		}
	}
	if (defined $cbp->{$k}->{'reloadscript'}) {
		if ($debug) {
			pb_log(1,"INFO: Executing (on $mac) $cbp->{$k}->{'reloadscript'}\n");
		} else {
			&$func("$cbp->{$k}->{'reloadscript'}");
		}
	}
}

if (defined $machine) {
	# Remote cleanup
	$chan->exec("rm -rf $ENV{'TMPDIR'}");
	$ssh2->disconnect();
}

# Cleanup
if (not $debug) {
	unlink("$tarfile");
} else {
	pb_log(0,"DEBUG: Please remove manually with rm -f $tarfile\n")
}
pb_log(2,"Exiting cb_distribute\n");
}

sub cb_add_to_cbp {

pb_log(3,"Entering into cb_addto_cbp\n");
my $type = 'files';
if (-d $File::Find::name) {
	$type = 'dirs';
}

my $destname = $File::Find::name;
# Target name is without the $dest part
$destname =~ s|^$dest||;
my ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,$atime,$mtime,$ctime,$blksize,$blocks) = stat("$File::Find::name") || die "Unable to stat $File::Find::name: $!";
$cbp->{"cb.full"}->{$type}->{$destname}->{'uid'} = $uid;
$cbp->{"cb.full"}->{$type}->{$destname}->{'gid'} = $gid;
$cbp->{"cb.full"}->{$type}->{$destname}->{'mode'} = $mode;
$cbp->{"cb.full"}->{$type}->{$destname}->{'mtime'} = $mtime;
pb_log(2,"Adding $destname ($uid,$gid,$mode) to cbp\n");
}