#!/usr/bin/perl -w
#
# Project Builder main application
#
# $Id$
#
# Copyright B. Cornec 2007
# Provided under the GPL v2

# Syntax: see at end

use strict 'vars';
use Getopt::Std;
use Data::Dumper;
use English;
use AppConfig qw(:argcount :expand);
use File::Basename;
use File::Copy;
use Time::localtime qw(localtime);
use POSIX qw(strftime);

# Global variables
use lib qw (lib);
use ProjectBuilder::Distribution qw (pb_distro_init);
use ProjectBuilder::Version qw (pb_version_init);
use ProjectBuilder::Base qw (pb_conf_read pb_conf_get pb_cms_init pb_mkdir_p pb_system pb_rm_rf pb_get_filters pb_filter_file pb_filter_file_pb pb_cms_export pb_cms_log pb_cms_isdiff pb_cms_copy pb_cms_checkout);

my %opts;					# CLI Options
my $action;					# action to realize
my $test = "FALSE";
my $option = "";
my @pkgs;
my $pbtag;					# Global Tag variable
my $pbver;					# Global Version variable
my $pbscript;				# Name of the script
my %pbver;					# per package
my %pbtag;					# per package
my $pbrev;					# Global REVISION variable
my @date=(localtime->sec(), localtime->min(), localtime->hour(), localtime->mday(), localtime->mon(), localtime->year(), localtime->wday(), localtime->yday(), localtime->isdst());
my $pbdate = strftime("%Y-%m-%d", @date);
my $pbdatecvs = strftime("%Y-%m-%d %H:%M:%S", @date);
my $debug = 0;
my $pbaccount;				# Login to use to connect to the VM
my $pbport;					# Port to use to connect to the VM
my $newver;					# New version to create
my $LOG = \*STDOUT;

getopts('a:hl:m:P:p:qr:s:tvV:',\%opts);

my ($projectbuilderver,$projectbuilderrev) = pb_version_init();
if (defined $opts{'h'}) {
	pb_syntax();
	exit(0);
}
if (defined $opts{'v'}) {
	$debug++;
}
if (defined $opts{'q'}) {
	$debug=-1;
}
if (defined $opts{'l'}) {
	open(LOG,"> $opts{'l'}") || die "Unable to log to $opts{'l'}: $!";
	$LOG = *LOG;
	$debug = 0  if ($debug == -1);
	}
# Handles test option
if (defined $opts{'t'}) {
	$test = "TRUE";
	# Works only for SVN
	$option = "-r BASE";
}

# Handle root of the project if defined
if (defined $opts{'r'}) {
	$ENV{'PBROOT'} = $opts{'r'};
}
# Handle virtual machines if any
if (defined $opts{'m'}) {
	$ENV{'PBVM'} = $opts{'m'};
}
if (defined $opts{'s'}) {
	$pbscript = $opts{'s'};
}
if (defined $opts{'a'}) {
	$pbaccount = $opts{'a'};
}
if (defined $opts{'P'}) {
	$pbport = $opts{'P'};
}
if (defined $opts{'V'}) {
	$newver = $opts{'V'};
}

# Get Action
$action = shift @ARGV;
die pb_syntax() if (not defined $action);

my ($pbrc, $filteredfiles, $defpkgdir, $extpkgdir);

# Handles project name if any
# And get global params
if (defined $opts{'p'}) {
	($ENV{'PBPROJ'},$debug,$LOG, $pbrc, $filteredfiles, $defpkgdir, $extpkgdir) 
	= pb_env_init($opts{'p'});
} else {
	($ENV{'PBPROJ'},$debug,$LOG, $pbrc, $filteredfiles, $defpkgdir, $extpkgdir) 
	= pb_env_init();
}

print $LOG "Project: $ENV{'PBPROJ'}\n" if ($debug >= 0);
print $LOG "Action: $action\n" if ($debug >= 0);

# Keep those project values to store them at the end each time
my $pbprojtag = $ENV{'PBTAG'};
my $pbprojver = $ENV{'PBVER'};

# Act depending on action
if ($action =~ /^cms2build$/) {
	pb_cms2build();
} elsif ($action =~ /^build2pkg$/) {
	pb_build2pkg();
} elsif ($action =~ /^cms2pkg$/) {
	pb_cms2build();
	pb_build2pkg();
} elsif ($action =~ /^build2ssh$/) {
	pb_build2ssh();
} elsif ($action =~ /^cms2ssh$/) {
	pb_cms2build();
	pb_build2ssh();
} elsif ($action =~ /^pkg2ssh$/) {
	pb_pkg2ssh();
} elsif ($action =~ /^build2vm$/) {
	pb_build2vm();
} elsif ($action =~ /^cms2vm$/) {
	pb_cms2build();
	pb_build2vm();
} elsif ($action =~ /^launchvm$/) {
	pb_launchvm($ENV{'PBVM'});
} elsif ($action =~ /^script2vm$/) {
	pb_script2vm($pbscript);
} elsif ($action =~ /^newver$/) {
	pb_newver();
} elsif ($action =~ /^clean$/) {
} else {
	print $LOG "'$action' is not available\n";
	pb_syntax();
}

sub pb_cms2build {

	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;
	my $cms=pb_cms_init($ENV{'PBPROJ'});

	my ($pkgv, $pkgt) = pb_conf_read("$ENV{'PBCONF'}/$ENV{'PBPROJ'}.pb","pkgver","pkgtag");

	# declare packager for filtering
	my ($tmp) = pb_conf_get("packager");
	my $pbpackager = $tmp->{$ENV{'PBPROJ'}};

	foreach my $pbpkg (@pkgs) {
		$ENV{'PBPKG'} = $pbpkg;
		if ((defined $pkgv) && (defined $pkgv->{$pbpkg})) {
			$pbver = $pkgv->{$pbpkg};
			$ENV{'PBVER'} = $pbver;
		} else {
			$pbver = $ENV{'PBVER'};
		}
		if ((defined $pkgt) && (defined $pkgt->{$pbpkg})) {
			$pbtag = $pkgt->{$pbpkg};
			$ENV{'PBTAG'} = $pbtag;
		} else {
			$pbtag = $ENV{'PBTAG'};
		}

		$pbrev = $ENV{'PBREVISION'};
		print $LOG "\n";
		print $LOG "Management of $pbpkg $pbver-$pbtag (rev $pbrev)\n";
		die "Unable to get env var PBDESTDIR" if (not defined $ENV{'PBDESTDIR'});
		# Clean up dest if necessary. The export will recreate it
		my $dest = "$ENV{'PBDESTDIR'}/$pbpkg-$pbver";
		pb_rm_rf($dest) if (-d $dest);

		# Export CMS tree for the concerned package to dest
		# And generate some additional files
		$OUTPUT_AUTOFLUSH=1;

		# computes in which dir we have to work
		my $dir = $defpkgdir->{$pbpkg};
		$dir = $extpkgdir->{$pbpkg} if (not defined $dir);
		print "def:".Dumper($defpkgdir)." ext: ".Dumper($extpkgdir)." \n" if ($debug >= 1);
		pb_cms_export($cms,$pbdatecvs,"$ENV{'PBROOT'}/$dir",$dest);

		# Extract cms log history and store it
		pb_cms_log($cms,"$ENV{'PBROOT'}/$dir","$dest/$ENV{'PBCMSLOGFILE'}");

		my %build;

		my ($ptr) = pb_conf_get("vmlist");
		foreach my $d (split(/,/,$ptr->{$ENV{'PBPROJ'}})) {
			my ($name,$ver) = split(/_/,$d);
			chomp($ver);
			my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init($name,$ver);
			print $LOG "DEBUG: distro tuple: ".Dumper($ddir, $dver, $dfam, $dtype, $pbsuf)."\n" if ($debug >= 1);
			print $LOG "DEBUG Filtering PBDATE => $pbdate, PBTAG => $pbtag, PBVER => $pbver\n" if ($debug >= 1);

			# Filter build files from the less precise up to the most with overloading
			# Filter all files found, keeping the name, and generating in dest

			# Find all build files first relatively to PBROOT
			my %bfiles;
			print $LOG "DEBUG dir: $ENV{'PBCONF'}/$pbpkg\n" if ($debug >= 1);
			$build{"$ddir-$dver"} = "yes";
			if (-d "$ENV{'PBCONF'}/$pbpkg/$dtype") {
				opendir(BDIR,"$ENV{'PBCONF'}/$pbpkg/$dtype") || die "Unable to open dir $ENV{'PBCONF'}/$pbpkg/$dtype: $!";
				foreach my $f (readdir(BDIR)) {
					next if ($f =~ /^\./);
					$bfiles{$f} = "$ENV{'PBCONF'}/$pbpkg/$dtype/$f";
					$bfiles{$f} =~ s~$ENV{'PBROOT'}~~;
				}
				closedir(BDIR);
			} elsif (-d "$ENV{'PBCONF'}/$pbpkg/$dfam") {
				opendir(BDIR,"$ENV{'PBCONF'}/$pbpkg/$dfam") || die "Unable to open dir $ENV{'PBCONF'}/$pbpkg/$dfam: $!";
				foreach my $f (readdir(BDIR)) {
					next if ($f =~ /^\./);
					$bfiles{$f} = "$ENV{'PBCONF'}/$pbpkg/$dfam/$f";
					$bfiles{$f} =~ s~$ENV{'PBROOT'}~~;
				}
				closedir(BDIR);
			} elsif (-d "$ENV{'PBCONF'}/$pbpkg/$ddir") {
				opendir(BDIR,"$ENV{'PBCONF'}/$pbpkg/$ddir") || die "Unable to open dir $ENV{'PBCONF'}/$pbpkg/$ddir: $!";
				foreach my $f (readdir(BDIR)) {
					next if ($f =~ /^\./);
					$bfiles{$f} = "$ENV{'PBCONF'}/$pbpkg/$ddir/$f";
					$bfiles{$f} =~ s~$ENV{'PBROOT'}~~;
				}
				closedir(BDIR);
			} elsif (-d "$ENV{'PBCONF'}/$pbpkg/$ddir-$dver") {
				opendir(BDIR,"$ENV{'PBCONF'}/$pbpkg/$ddir-$dver") || die "Unable to open dir $ENV{'PBCONF'}/$pbpkg/$ddir-$dver: $!";
				foreach my $f (readdir(BDIR)) {
					next if ($f =~ /^\./);
					$bfiles{$f} = "$ENV{'PBCONF'}/$pbpkg/$ddir-$dver/$f";
					$bfiles{$f} =~ s~$ENV{'PBROOT'}~~;
				}
				closedir(BDIR);
			} else {
				$build{"$ddir-$dver"} = "no";
				next;
			}
			print $LOG "DEBUG bfiles: ".Dumper(\%bfiles)."\n" if ($debug >= 1);

			# Get all filters to apply
			my $ptr = pb_get_filters($pbpkg, $dtype, $dfam, $ddir, $dver);

			# Apply now all the filters on all the files concerned
			# destination dir depends on the type of file
			if (defined $ptr) {
				foreach my $f (values %bfiles) {
					pb_filter_file_pb("$ENV{'PBROOT'}/$f",$ptr,"$dest/pbconf/$ddir-$dver/".basename($f),$dtype,$pbsuf,$pbpkg,$pbver,$pbtag,$pbrev,$pbdate,$defpkgdir,$extpkgdir,$pbpackager);
				}
			}
		}
		if ($debug >= 0) {
			my @found;
			my @notfound;
			foreach my $b (keys %build) {
				push @found,$b if ($build{$b} =~ /yes/);
				push @notfound,$b if ($build{$b} =~ /no/);
			}
			print $LOG "Build files generated for ".join(',',@found)."\n";
			print $LOG "No Build files found for ".join(',',@notfound)."\n";
		}
		# Prepare the dest directory for archive
		if (-x "$ENV{'PBCONF'}/$pbpkg/pbinit") {
			#pb_system("cd $dest ; $ENV{'PBCONF'}/$pbpkg/pbinit","Executing init script $ENV{'PBCONF'}/$pbpkg/pbinit");
			print $LOG "Executing init script $ENV{'PBCONF'}/$pbpkg/pbinit\n";
			system("cd $dest ; $ENV{'PBCONF'}/$pbpkg/pbinit");
		}

		# Get the generic filter (all.pbf) and 
		# apply those to the non-build files including those
		# generated by pbinit if applicable

		# Get only all.pbf filter
		my $ptr = pb_get_filters($pbpkg);

		my $liste ="";
		if (defined $filteredfiles->{$pbpkg}) {
			foreach my $f (split(/,/,$filteredfiles->{$pbpkg})) {
				pb_filter_file("$ENV{'PBROOT'}/$dir/$f",$ptr,"$dest/$f",$pbpkg,$pbver,$pbtag,$pbrev,$pbdate,$pbpackager);
				$liste = "$dest/$f $liste";
			}
		}
		print "$liste have been filtered\n";

		# Archive dest dir
		chdir "$ENV{'PBDESTDIR'}" || die "Unable to change dir to $ENV{'PBDESTDIR'}";
		# Possibility to look at PBSRC to guess more the filename
		pb_system("tar cfz $pbpkg-$pbver.tar.gz $pbpkg-$pbver","Creating $pbpkg tar files compressed");
		print $LOG "Under $ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz\n" if ($debug >= 0);

		# Keep track of what is generated for default
		open(LAST,"> $pbrc->{$ENV{'PBPROJ'}}") || die "Unable to create $pbrc->{$ENV{'PBPROJ'}}";
		print LAST "pbroot $pbprojver-$pbprojtag = $ENV{'PBROOT'}\n";
		close(LAST);

		# Keep track of per package version
		if (! -f "$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb") {
			open(PKG,">$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb") || die "Unable to create $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb";
			print PKG "# Empty\n";
			close(PKG);
		}
		my ($pkg) = pb_conf_read("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
		$pkg = { } if (not defined $pkg);
		if ((not defined $pkg->{$pbpkg}) || ($pkg->{$pbpkg} ne "$pbver-$pbtag")) {
			$pkg->{$pbpkg} = "$pbver-$pbtag";
		}

		print $LOG "DEBUG pkg: ".Dumper($pkg)."\n" if ($debug >= 1);
		open(PKG,"> $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb") || die "Unable to create $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb";
		foreach my $p (keys %$pkg) {
			print PKG "pbpkg $p = $pkg->{$p}\n";
		}
		close(PKG);
	}
}

sub pb_build2pkg {

	# Get list of packages to build
	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;

	# Get the running distro to build on
	my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init();
	print $LOG "DEBUG: distro tuple: ".join(',',($ddir, $dver, $dfam, $dtype, $pbsuf))."\n" if ($debug >= 1);

	# Get content saved in cms2build
	my ($pkg) = pb_conf_read("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
	$pkg = { } if (not defined $pkg);

	# declare packager
	my ($tmp) = pb_conf_get("packager");
	my $pbpackager = $tmp->{$ENV{'PBPROJ'}};

	chdir "$ENV{'PBBUILDDIR'}";
	my $made = ""; # pkgs made during build
	foreach my $pbpkg (@pkgs) {
		my $vertag = $pkg->{$pbpkg};
		# get the version of the current package - maybe different
		($pbver,$pbtag) = split(/-/,$vertag);

		my $src="$ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz";
		# Suse 10.0 forces tar.bz2 usage :-(
		if (($ddir eq "suse") && ($dver eq "10.0")) {
			print "SuSE 10.0 needs bz2 type of packages so recompressing...\n";
			my $newsrc="$ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.bz2";
			system "gzip -cd $src | bzip2 -c6 > $newsrc";
			$src = $newsrc;
		}
		print $LOG "Source file: $src\n" if ($debug >= 0);

		print $LOG "Working directory: $ENV{'PBBUILDDIR'}\n" if ($debug >= 0);
		if ($dtype eq "rpm") {
			foreach my $d ('RPMS','SRPMS','SPECS','SOURCES','BUILD') {
				if (! -d "$ENV{'PBBUILDDIR'}/$d") {
				pb_mkdir_p("$ENV{'PBBUILDDIR'}/$d") || die "Please ensure that you can write into $ENV{'PBBUILDDIR'} to create $d\nchown the $ENV{'PBBUILDDIR'} directory to your uid";
				}
			}

			symlink "$src","$ENV{'PBBUILDDIR'}/SOURCES/".basename($src) || die "Unable to symlink $src in $ENV{'PBBUILDDIR'}/SOURCES";
			# We need to first extract the spec file
			my @specfile;
			@specfile = pb_extract_build_files($src,"$pbpkg-$pbver/pbconf/$ddir-$dver/","$ENV{'PBBUILDDIR'}/SPECS");

			print $LOG "specfile: ".Dumper(\@specfile)."\n" if ($debug >= 1);
			# set LANGUAGE to check for correct log messages
			$ENV{'LANGUAGE'}="C";
			#system("ls -R $ENV{'PBBUILDDIR'}") if ($debug >= 1);
			foreach my $f (@specfile) {
				if ($f =~ /\.spec$/) {
					pb_system("rpmbuild --define \"packager $pbpackager\" --define \"_topdir $ENV{'PBBUILDDIR'}\" -ba $f","Building package with $f under $ENV{'PBBUILDDIR'}");
					last;
				}
			}
			$made="$made RPMS/*/$pbpkg-$pbver-$pbtag$pbsuf.*.rpm SRPMS/$pbpkg-$pbver-$pbtag$pbsuf.src.rpm";
			if (-f "/usr/bin/rpmlint") {
				pb_system("rpmlint $made","Checking validity of rpms with rpmlint");
			}
		} elsif ($dtype eq "deb") {
			chdir "$ENV{'PBBUILDDIR'}" || die "Unable to chdir to $ENV{'PBBUILDDIR'}";
			pb_system("tar xpfz $src","Extracting sources");

			chdir "$pbpkg-$pbver" || die "Unable to chdir to $pbpkg-$pbver";
			symlink "pbconf/$ddir-$dver","debian" || die "Unable to symlink to pbconf/$ddir-$dver";
			chmod 0755,"debian/rules";
			pb_system("dpkg-buildpackage -us -uc -rfakeroot","Building package");
			$made="$made $pbpkg"."_*.deb $pbpkg"."_*.dsc $pbpkg"."_*.tar.gz";
		} elsif ($dtype eq "ebuild") {
			my @ebuildfile;
			# For gentoo we need to take pb as subsystem name
			pb_mkdir_p("$ENV{'PBBUILDDIR'}/portage/pb/$pbpkg") if (! -d "$ENV{'PBBUILDDIR'}/portage/pb/$pbpkg");

			# We need to first extract the ebuild file
			@ebuildfile = pb_extract_build_files($src,"$pbpkg-$pbver/pbconf/$ddir-$dver/","$ENV{'PBBUILDDIR'}/portage/pb/$pbpkg");

			# Prepare the build env for gentoo
			my $found = 0;
			my $pbbd = $ENV{'PBBUILDDIR'};
			$pbbd =~ s|/|\\/|g;
			open(MAKE,"/etc/make.conf") || die "Unable to open /etc/make.conf";
			while (<MAKE>) {
				$found = 1 if (/$pbbd\/portage/);
			}
			close(MAKE);
			if ($found == 0) {
				pb_system("sudo \'echo \"$ENV{'PBBUILDDIR'}/portage\" >> /etc/make.conf\'");
			}
			$found = 0;
			open(KEYW,"/etc/portage/package.keywords") || die "Unable to open /etc/portage/package.keywords";
			while (<KEYW>) {
				$found = 1 if (/portage\/pb/);
			}
			close(KEYW);
			if ($found == 0) {
				pb_system("sudo \'echo \"portage/pb\" >> /etc/portage/package.keywords\'");
			}

			# Build
			foreach my $f (@ebuildfile) {
				if ($f =~ /\.ebuild$/) {
					pb_system("ebuild $f digest ; ebuild $f package");
				}
			}
			print $LOG "ebuild file: ".Dumper(\@ebuildfile)."\n" if ($debug >= 1);

			$made="$made portage/pb/$pbpkg/$pbpkg-$pbver.ebuild";
		} elsif ($dtype eq "slackware") {
			$made="$made build-$pbpkg/$pbpkg-$pbver-*-$pbtag.tgz";
			pb_mkdir_p("$ENV{'PBBUILDDIR'}/install") if (! -d "$ENV{'PBBUILDDIR'}/install");
		} else {
			die "Unknown dtype format $dtype";
		}
	}
	# Keep track of what is generated so that we can get them back from VMs
	open(KEEP,"> $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to create $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
	print KEEP "$made\n";
	close(KEEP);
}

sub pb_build2ssh {
	pb_send2ssh("Sources");
}

sub pb_pkg2ssh {
	pb_send2ssh("Packages");
}

# By default deliver to the the public site hosting the 
# ftp structure (or whatever) or a VM
sub pb_send2ssh {

	my $cmt = shift;
	my $vm = shift || undef;
	my $vmexist = shift || 0;			# 0 is FALSE
	my $vmpid = shift || 0;				# 0 is FALSE
	my $host = shift || "sshhost";
	my $login = shift || "sshlogin";
	my $dir = shift || "sshdir";
	my $port = shift || "sshport";
	my $tmout = shift || "vmtmout";
	my $cmd = "";

	# Get list of packages to build
	my $ptr = pb_get_pkg($defpkgdir,$extpkgdir);
	@pkgs = @$ptr;

	# Get the running distro to consider
	my ($odir,$over) = (undef, undef);
	if (defined $vm) {
		($odir,$over) = split(/_/,$vm);
	}
	my ($ddir, $dver, $dfam, $dtype, $pbsuf) = pb_distro_init($odir,$over);
	print $LOG "DEBUG: distro tuple: ".join(',',($ddir, $dver, $dfam, $dtype, $pbsuf))."\n" if ($debug >= 1);

	# Get content saved in cms2build
	my ($pkg) = pb_conf_read("$ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb","pbpkg");
	$pkg = { } if (not defined $pkg);

	my $src = "";
	chdir "$ENV{'PBBUILDDIR'}";
	foreach my $pbpkg (@pkgs) {
		my $vertag = $pkg->{$pbpkg};
		# get the version of the current package - maybe different
		($pbver,$pbtag) = split(/-/,$vertag);

		if (($cmt eq "Sources") || ($cmt eq "VMs")) {
			$src = "$src $ENV{'PBDESTDIR'}/$pbpkg-$pbver.tar.gz";
			if ($cmd eq "") {
				$cmd = "ln -sf $pbpkg-$pbver.tar.gz $pbpkg-latest.tar.gz";
			} else {
				$cmd = "$cmd ; ln -sf $pbpkg-$pbver.tar.gz $pbpkg-latest.tar.gz";
			}
		}
	}
	if ($cmt eq "VMs") {
		$src="$src $ENV{'PBDESTDIR'}/pbscript $ENV{'PBCONF'}/$ENV{'PBPROJ'}.pb $ENV{'PBDESTDIR'}/$pbprojver-$pbprojtag.pb $ENV{'PBETC'}";
	} elsif ($cmt eq "Script") {
		$src="$src $ENV{'PBDESTDIR'}/pbscript";
	} elsif ($cmt eq "Packages") {
		# Get package list from file made during build2pkg
		open(KEEP,"$ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to read $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		$src = <KEEP>;
		chomp($src);
		close(KEEP);
		if ($dtype eq "rpm") {
			# Also make a pbscript to generate yum/urpmi bases
			# $src = "$src $ENV{'PBDESTDIR'}/pbscript"
		} elsif ($dtype eq "deb") {
			# Also make a pbscript to generate apt bases
			# $src = "$src $ENV{'PBDESTDIR'}/pbscript"
		}
	}
	# Remove potential leading spaces (cause pb with basename)
	$src =~ s/^ *//;
	my $basesrc = "";
	foreach my $i (split(/ +/,$src)) {
		$basesrc .= " ".basename($i);
	}

	print $LOG "Sources handled ($cmt): $src\n" if ($debug >= 0);
	my ($sshhost,$sshlogin,$sshdir,$sshport,$vmtmout) = pb_conf_get($host,$login,$dir,$port,$tmout);
	my $mac = "$sshlogin->{$ENV{'PBPROJ'}}\@$sshhost->{$ENV{'PBPROJ'}}";
	# Overwrite account value if passed as parameter
	$mac = "$pbaccount\@$sshhost->{$ENV{'PBPROJ'}}" if (defined $pbaccount);
	$port = "$pbport" if (defined $pbport);
	my $tdir;
	my $bdir;
	if (($cmt eq "Sources") || ($cmt eq "Script")) {
		$tdir = "$sshdir->{$ENV{'PBPROJ'}}/src";
	} elsif ($cmt eq "VMs") {
		$tdir = dirname("$sshdir->{$ENV{'PBPROJ'}}")."/delivery";
		$bdir = dirname("$sshdir->{$ENV{'PBPROJ'}}")."/build";
		# Remove a potential $ENV{'HOME'} as bdir should be relative to pb's home
		$bdir =~ s|\$ENV.+\}/||;
	} elsif ($cmt eq "Packages") {
		$tdir = "$sshdir->{$ENV{'PBPROJ'}}/$ddir/$dver";
	} else {
		return;
	}
	# Remove a potential $ENV{'HOME'} as tdir should be relative to pb's home
	$tdir =~ s|\$ENV.+\}/||;

	$port = $sshport->{$ENV{'PBPROJ'}};
	my $tm = $vmtmout->{$ENV{'PBPROJ'}};
	pb_system("ssh -q -p $port $mac \"mkdir -p $tdir ; cd $tdir ; echo \'for i in $basesrc; do if [ -f \$i ]; then rm -f \$i; fi; done\ ; $cmd' | bash\"","Preparing $tdir on $mac");
	pb_system("cd $ENV{'PBBUILDDIR'} ; scp -p -P $port $src $mac:$tdir 2> /dev/null","$cmt delivery in $tdir on $mac");
	pb_system("ssh -q -p $port $mac \"echo \'cd $tdir ; if [ -f pbscript ]; then ./pbscript; fi\' | bash\"","Executing pbscript on $mac  if needed");
	if ($cmt eq "VMs") {
		# Get back info on pkg produced, compute their name and get them from the VM
		pb_system("scp -p -P $port $mac:$bdir/pbgen-$pbprojver-$pbprojtag $ENV{'PBBUILDDIR'} 2> /dev/null","Get package names in $bdir on $mac");
		open(KEEP,"$ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to read $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		my $src = <KEEP>;
		chomp($src);
		close(KEEP);
		$src =~ s/^ *//;
		pb_mkdir_p("$ENV{'PBBUILDDIR'}/$odir/$over");
		# Change pgben to make the next send2ssh happy
		my $made = "";
		open(KEEP,"> $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag") || die "Unable to write $ENV{'PBBUILDDIR'}/pbgen-$pbprojver-$pbprojtag";
		foreach my $p (split(/ +/,$src)) {
			my $j = basename($p);
			pb_system("scp -p -P $port $mac:\'$bdir/$p\' $ENV{'PBBUILDDIR'}/$odir/$over 2> /dev/null","Package recovery of $j in $bdir from $mac");
			$made="$made $odir/$over/$j" if (($dtype ne "rpm") || ($j !~ /.src.rpm$/));
		}
		print KEEP "$made\n";
		close(KEEP);
		pb_system("ssh -q -p $port $mac \"rm -rf $tdir $bdir\"","VM cleanup on $mac");
		if (! $vmexist) {
			pb_system("ssh -q -p $port $mac \"sudo /sbin/halt -p \"; sleep $tm ; echo \'if [ -d /proc/$vmpid ]; then kill -9 $vmpid; fi \' | bash ; sleep 10","VM $vm halt (pid $vmpid)");
		}
		pb_send2ssh("Packages","$odir"."_"."$over");
		pb_rm_rf("$ENV{'PBBUILDDIR'}/$odir");
	}
}

sub pb_script2vm {
	my $pbscript=shift;

	# Prepare the script to be executed on the VM
	# in $ENV{'PBDESTDIR'}/pbscript
	if ((defined $pbscript ) && ($pbscript ne "$ENV{'PBDESTDIR'}/pbscript")) {
		copy($pbscript,"$ENV{'PBDESTDIR'}/pbscript") || die "Unable to create $ENV{'PBDESTDIR'}/pbscript";
		chmod 0755,"$ENV{'PBDESTDIR'}/pbscript";
	}

	my ($vm,$all) = pb_get_vm();

	foreach my $v (@$vm) {
		# Launch the VM
		my ($vmexist,$vmpid) = pb_launchvm($v);

		# Gather all required files to send them to the VM 
		# and launch the build thourgh pbscript
		pb_send2ssh("Script","$v",$vmexist,$vmpid,"vmhost","vmlogin","pbrc","vmport","vmtmout");

	}
}

sub pb_launchvm {
	my $vm = shift;

	die "No VM defined, unable to launch" if (not defined $vm);
	# Keep only the first VM in case many were given
	$vm =~ s/,.*//;

	# Launch the VMs
	my ($ptr,$vmopt,$vmport,$vmpath,$vmtmout) = pb_conf_get("vmtype","vmopt","vmport","vmpath","vmtmout");
	my $vmtype = $ptr->{$ENV{'PBPROJ'}};
	if (defined $vmopt->{$ENV{'PBPROJ'}}) {
		$ENV{'PBVMOPT'} = $vmopt->{$ENV{'PBPROJ'}};
	} else {
		$ENV{'PBVMOPT'} = "";
	}
	$vmport->{$ENV{'PBPROJ'}} = "$pbport" if (defined $pbport);

	my $cmd;
	my $vmcmd;		# has to be used for pb_check_ps
	my $vmm;		# has to be used for pb_check_ps
	if ($vmtype eq "qemu") {
		my $arch = `uname -m`;
		chomp($arch);
		my $qemucmd32;
		my $qemucmd64;
		if ($arch eq "x86_64") {
			$qemucmd32 = "/usr/bin/qemu-system-i386";
			$qemucmd64 = "/usr/bin/qemu";
		} else {
			$qemucmd32 = "/usr/bin/qemu";
			$qemucmd64 = "/usr/bin/qemu-system-x86_64";
		}
		if ($vm =~ /_64/) {
			$vmcmd = "$qemucmd64 -no-kqemu";
		} else {
			$vmcmd = "$qemucmd32";
		}
		$vmm = "$vmpath->{$ENV{'PBPROJ'}}/$vm.qemu";
		if (! -f "$vmm") {
			die "Unable to find VM $vmm";
		}
		$cmd = "$vmcmd $ENV{'PBVMOPT'} -redir tcp:$vmport->{$ENV{'PBPROJ'}}:10.0.2.15:22 $vmm"
	} elsif ($vmtype eq "xen") {
	} elsif ($vmtype eq "vmware") {
	} else {
		die "VM of type $vmtype not supported. Report to the dev team";
	}
	my ($tmpcmd,$void) = split(/ +/,$cmd);
	my $vmexist = pb_check_ps($tmpcmd,$vmm);
	my $vmpid = 0;
	if (! $vmexist) {
		pb_system("$cmd &","Launching the VM $vmm");
		pb_system("sleep $vmtmout->{$ENV{'PBPROJ'}}","Waiting for VM $vm to come up");
		$vmpid = pb_check_ps($tmpcmd,$vmm);
	} else {
		print "Found an existing VM $vmm (pid $vmexist)\n";
	}
	return($vmexist,$vmpid);
}

sub pb_build2vm {
	# Prepare the script to be executed on the VM
	# in $ENV{'PBDESTDIR'}/pbscript
	my ($ntp) = pb_conf_get("vmntp");
	my $vmntp = $ntp->{$ENV{'PBPROJ'}};
	open(SCRIPT,"> $ENV{'PBDESTDIR'}/pbscript") || die "Unable to create $ENV{'PBDESTDIR'}/pbscript";
	print SCRIPT "#!/bin/bash\n";
	print SCRIPT "echo ... Execution needed\n";
	print SCRIPT "# This is in directory delivery\n";
	print SCRIPT "# Setup the variables required for building\n";
	print SCRIPT "export PBPROJ=$ENV{'PBPROJ'}\n";
	print SCRIPT "# Preparation for pb\n";
	print SCRIPT "mkdir -p ../pbconf\n";
	print SCRIPT "mv $ENV{'PBPROJ'}.pb ../pbconf\n";
	print SCRIPT "mv .pbrc \$HOME\n";
	print SCRIPT "cd ..\n";
	# Force new date to be in the future compared to the date of the tar file by removing 1 minute
	my @date=(localtime->sec(), localtime->min(), localtime->hour(), localtime->mday(), localtime->mon(), localtime->year(), localtime->wday(), localtime->yday(), localtime->isdst());
	$date[1]--;
	my $upddate = strftime("%m%d%H%M%Y", @date);
	print SCRIPT "echo Setting up date on $vmntp...\n";
	print SCRIPT "sudo date $upddate\n";
	print SCRIPT "export PBROOT=\`pwd\`\n";
	print SCRIPT "# Build\n";
	my $p = "";
	$p = $ARGV[0] if (defined $ARGV[0]);
	print SCRIPT "echo Building packages on VM...\n";
	print SCRIPT "pb -p $ENV{'PBPROJ'} build2pkg $p\n";
	close(SCRIPT);
	chmod 0755,"$ENV{'PBDESTDIR'}/pbscript";

	my ($vm,$all) = pb_get_vm();

	# Send tar files when we do a global generation
	pb_build2ssh() if ($all == 1);

	foreach my $v (@$vm) {
		# Launch the VM
		my ($vmexist,$vmpid) = pb_launchvm($v);

		# Gather all required files to send them to the VM 
		# and launch the build thourgh pbscript
		pb_send2ssh("VMs","$v",$vmexist,$vmpid,"vmhost","vmlogin","pbrc","vmport","vmtmout");
	}
}

sub pb_newver {

	die "-V Version parameter needed" if ((not defined $newver) || ($newver eq ""));
	my $cms=pb_cms_init($ENV{'PBPROJ'});
	if ($cms->{$ENV{'PBPROJ'}} ne "svn") {
		die "Only SVN is supported at the moment";
	}
	my $res = pb_cms_isdiff($cms);
	die "You need to have no differences before creating a new version" if ($res != 0);
	my $cmsurl = pb_cms_getinfo($cms);
	my $newurl = dirname($cmsurl)."/$newver";
	pb_cms_copy($cms,$cmsurl,$newurl);
	pb_cms_checkout($cms,$newurl,"$ENV{'PBROOT'}/../$newver");
	my $oldver=basename($cmsurl);
	open(FILE,"$ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb") || die "Unable to open $ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb";
	open(OUT,"> $ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new") || die "Unable to write to $ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new";
	while(<FILE>) {
		s/projver\s+$ENV{'PBPROJ'}\s*=\s*$oldver/projver $ENV{'PBPROJ'} = $newver/;
		print OUT $_;
	}
	close(FILE);
	close(OUT);
	rename("$ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb.new","$ENV{'PBROOT'}/../$newver/pbconf/$ENV{'PBPROJ'}.pb");
	pb_cms_checkin($cms,"$ENV{'PBROOT'}/../$newver");
}

sub pb_get_pkg {

my @pkgs;
my $defpkgdir = shift;
my $extpkgdir = shift;

# Get packages list
if (not defined $ARGV[0]) {
	@pkgs = keys %$defpkgdir;
} elsif ($ARGV[0] =~ /^all$/) {
	@pkgs = keys %$defpkgdir;
	push(@pkgs, keys %$extpkgdir);
} else {
	@pkgs = @ARGV;
}
print $LOG "Packages: ".join(',',@pkgs)."\n" if ($debug >= 0);
return(\@pkgs);
}

#
# Return the list of VMs we are working on
# $all is a flag to know if we return all of them 
# or only some (if all we publish also tar files in addition to pkgs
#
sub pb_get_vm {

my @vm;
my $all = 0;

# Get VM list
if ((not defined $ENV{'PBVM'}) || ($ENV{'PBVM'} =~ /^all$/)) {
	my ($ptr) = pb_conf_get("vmlist");
	$ENV{'PBVM'} = $ptr->{$ENV{'PBPROJ'}};
	$all = 1;
}
@vm = split(/,/,$ENV{'PBVM'});
print $LOG "VMs: ".join(',',@vm)."\n";
return(\@vm,$all);
}

# Returns the pid of a running VM command using a specific VM file
sub pb_check_ps {
	my $vmcmd = shift;
	my $vmm = shift;
	my $vmexist = 0;		# FALSE by default

	open(PS, "ps auxhww|") || die "Unable to call ps";
	while (<PS>) {
		next if (! /$vmcmd/);
		next if (! /$vmm/);
		my ($void1, $void2);
		($void1, $vmexist, $void2) = split(/ +/);
		last;
	}
	return($vmexist);
}


sub pb_extract_build_files {

my $src=shift;
my $dir=shift;
my $ddir=shift;
my @files;

if ($src =~ /tar\.gz$/) {
	pb_system("tar xfpz $src $dir","Extracting build files");
} elsif ($src =~ /tar\.bz2$/) {
	pb_system("tar xfpj $src $dir","Extracting build files");
} else {
	die "Unknown compression algorithm for $src";
}
opendir(DIR,"$dir") || die "Unable to open directory $dir";
foreach my $f (readdir(DIR)) {
	next if ($f =~ /^\./);
	move("$dir/$f","$ddir") || die "Unable to move $dir/$f to $ddir";
	print $LOG "mv $dir/$f $ddir\n" if ($debug >= 1);
	push @files,"$ddir/$f";
}
closedir(DIR);
# Not enough but still a first cleanup
pb_rm_rf("$dir");
return(@files);
}

sub pb_syntax {

	print "pb (aka project-builder) Version $projectbuilderver-$projectbuilderrev\n";
	print "\n";
	print "Syntax: pb [-vhqt][-r pbroot][-p project][[-s script -a account -P port] -m \"mach-1[,...]\"] <action> [<pkg1>...]\n";
	print "\n";
	print "-h : This help file\n";
	print "-q : Quiet mode\n";
	print "-t : Test mode (not done yet)\n";
	print "-v : Verbose mode\n";
	print "\n";
	print "-m machine : Name of the Virtual Machines (VM) you want\n";
	print "             to build on (coma separated). All if none precised\n";
	print "             (or use the env variable PBVM)       \n";
	print "\n";
	print "-s script  : Name of the script you want\n";
	print "             to execute on the related VMs.\n";
	print "\n";
	print "-a account : Name of the account to use\n";
	print "             to connect on the related VMs.\n";
	print "\n";
	print "-P port    : Number of the port to use\n";
	print "             to connect on the related VMs.\n";
	print "\n";
	print "-p project : Name of the project you're working on\n";
	print "             (or use the env variable PBPROJ)     \n";
	print "\n";
	print "-r pbroot  : Path Name of project under the CMS \n";
	print "             (or use the env variable PBROOT)   \n";
	print "\n";
	print "-V newver  : New version of the project to create\n";
	print "             from the current one.              \n";
	print "\n";
	print "<action> can be:\n";
	print "\n";
	print "\tcms2build: Create tar files for the project under your CMS\n";
	print "\t           CMS supported are SVN and CVS\n";
	print "\t           parameters are packages to build\n";
	print "\t           if not using default list\n";
	print "\n";
	print "\tbuild2pkg: Create packages for your running distribution  \n";
	print "\n";
	print "\tcms2pkg:   cms2build + build2pkg\n";
	print "\n";
	print "\tbuild2ssh: Send the tar files to a SSH host               \n";
	print "\n";
	print "\tcms2ssh:   cms2build + build2ssh\n";
	print "\n";
	print "\tpkg2ssh:   Send the packages built to a SSH host          \n";
	print "\n";
	print "\tbuild2vm:  Create packages in VMs, launching them if needed\n";
	print "\t           and send those packages to a SSH host once built\n";
	print "\t           VM type supported are QEMU            \n";
	print "\n";
	print "\tcms2vm:    cms2build + build2vm\n";
	print "\n";
	print "\tlaunchvm:  Launch one virtual machine\n";
	print "\n";
	print "\tscript2vm: Launch one virtual machine if needed        \n";
	print "\t			and executes a script on it                 \n";
	print "\n";
	print "\tnewver:	Create a new version of the project derived \n";
	print "\t			from the current one                        \n";
	print "\n";
}
